cgi/pkgreport.cgi

   1 #!/usr/bin/perl -wT
   2
   3 package debbugs;
   4
   5 use strict;
   6 use POSIX qw(strftime tzset nice);
   7
   8 #require '/usr/lib/debbugs/errorlib';
   9 require './common.pl';
  10
  11 require '/etc/debbugs/config';
  12 require '/etc/debbugs/text';
  13
  14 use Debbugs::User;
  15
  16 use vars qw($gPackagePages $gWebDomain %gSeverityDisplay @gSeverityList);
  17
  18 if (defined $ENV{REQUEST_METHOD} and $ENV{REQUEST_METHOD} eq 'HEAD') {
  19     print "Content-Type: text/html; charset=utf-8\n\n";
  20     exit 0;
  21 }
  22
  23 nice(5);
  24
  25 my $userAgent = detect_user_agent();
  26 my %param = readparse();
  27
  28 my $repeatmerged = ($param{'repeatmerged'} || "yes") eq "yes";
  29 my $archive = ($param{'archive'} || "no") eq "yes";
  30 my $include = $param{'&include'} || $param{'include'} || "";
  31 my $exclude = $param{'&exclude'} || $param{'exclude'} || "";
  32
  33 my $users = $param{'users'} || "";
  34
  35 my $ordering = $param{'ordering'};
  36 my $raw_sort = ($param{'raw'} || "no") eq "yes";
  37 my $old_view = ($param{'oldview'} || "no") eq "yes";
  38 unless (defined $ordering) {
  39    $ordering = "normal";
  40    $ordering = "oldview" if $old_view;
  41    $ordering = "raw" if $raw_sort;
  42 }
  43
  44 my $bug_rev = ($param{'bug-rev'} || "no") eq "yes";
  45 my $pend_rev = ($param{'pend-rev'} || "no") eq "yes";
  46 my $sev_rev = ($param{'sev-rev'} || "no") eq "yes";
  47 my $pend_exc = $param{'&pend-exc'} || $param{'pend-exc'} || "";
  48 my $pend_inc = $param{'&pend-inc'} || $param{'pend-inc'} || "";
  49 my $sev_exc = $param{'&sev-exc'} || $param{'sev-exc'} || "";
  50 my $sev_inc = $param{'&sev-inc'} || $param{'sev-inc'} || "";
  51 my $maxdays = ($param{'maxdays'} || -1);
  52 my $mindays = ($param{'mindays'} || 0);
  53 my $version = $param{'version'} || undef;
  54 my $dist = $param{'dist'} || undef;
  55 my $arch = $param{'arch'} || undef;
  56 my $show_list_header = ($param{'show_list_header'} || $userAgent->{'show_list_header'} || "yes" ) eq "yes";
  57 my $show_list_footer = ($param{'show_list_footer'} || $userAgent->{'show_list_footer'} || "yes" ) eq "yes";
  58
  59 {
  60     if (defined $param{'vt'}) {
  61         my $vt = $param{'vt'};
  62         if ($vt eq "none") { $dist = undef; $arch = undef; $version = undef; }
  63         if ($vt eq "bysuite") {
  64             $version = undef;
  65             $arch = undef if ($arch eq "any");
  66         }
  67         if ($vt eq "bypkg" || $vt eq "bysrc") { $dist = undef; $arch = undef; }
  68     }
  69     if (defined $param{'includesubj'}) {
  70         my $is = $param{'includesubj'};
  71         $include .= "," . join(",", map { "subj:$_" } (split /[\s,]+/, $is));
  72     }
  73     if (defined $param{'excludesubj'}) {
  74         my $es = $param{'excludesubj'};
  75         $exclude .= "," . join(",", map { "subj:$_" } (split /[\s,]+/, $es));
  76     }
  77 }
  78
  79
  80 my %hidden = map { $_, 1 } qw(status severity classification);
  81 my %cats = (
  82     "status" => [ {
  83         "nam" => "Status",
  84         "pri" => [map { "pending=$_" }
  85             qw(pending forwarded pending-fixed fixed done absent)],
  86         "ttl" => ["Outstanding","Forwarded","Pending Upload",
  87                   "Fixed in NMU","Resolved","From other Branch"],
  88         "def" => "Unknown Pending Status",
  89         "ord" => [0,1,2,3,4,5,6],
  90     } ],
  91     "severity" => [ {
  92         "nam" => "Severity",
  93         "pri" => [map { "severity=$_" } @debbugs::gSeverityList],
  94         "ttl" => [map { $debbugs::gSeverityDisplay{$_} } @debbugs::gSeverityList],
  95         "def" => "Unknown Severity",
  96         "ord" => [0,1,2,3,4,5,6,7],
  97     } ],
  98     "classification" => [ {
  99         "nam" => "Classification",
 100         "pri" => [qw(pending=pending+tag=wontfix
 101                      pending=pending+tag=moreinfo
 102                      pending=pending+tag=patch
 103                      pending=pending+tag=confirmed
 104                      pending=pending)],
 105         "ttl" => ["Will Not Fix","More information needed",
 106                   "Patch Available","Confirmed"],
 107         "def" => "Unclassified",
 108         "ord" => [2,3,4,1,0,5],
 109     } ],
 110     "oldview" => [ qw(status severity) ],
 111     "normal" => [ qw(status severity classification) ],
 112 );
 113
 114 my ($pkg, $src, $maint, $maintenc, $submitter, $severity, $status, $tag, $usertag);
 115
 116 my %which = (
 117         'pkg' => \$pkg,
 118         'src' => \$src,
 119         'maint' => \$maint,
 120         'maintenc' => \$maintenc,
 121         'submitter' => \$submitter,
 122         'severity' => \$severity,
 123         'tag' => \$tag,
 124         'usertag' => \$usertag,
 125         );
 126 my @allowedEmpty = ( 'maint' );
 127
 128 my $found;
 129 foreach ( keys %which ) {
 130         $status = $param{'status'} || 'open' if /^severity$/;
 131         if (($found = $param{$_})) {
 132                 ${ $which{$_} } = $found;
 133                 last;
 134         }
 135 }
 136 if (!$found && !$archive) {
 137         foreach ( @allowedEmpty ) {
 138                 if (exists($param{$_})) {
 139                         ${ $which{$_} } = '';
 140                         $found = 1;
 141                         last;
 142                 }
 143         }
 144 }
 145 if (!$found) {
 146         my $which;
 147         if (($which = $param{'which'})) {
 148                 if (grep( /^\Q$which\E$/, @allowedEmpty)) {
 149                         ${ $which{$which} } = $param{'data'};
 150                         $found = 1;
 151                 } elsif (($found = $param{'data'})) {
 152                         ${ $which{$which} } = $found if (exists($which{$which}));
 153                 }
 154         }
 155 }
 156 quitcgi("You have to choose something to select by") if (!$found);
 157
 158 my %bugusertags;
 159 my %ut;
 160 for my $user (split /[\s*,]+/, $users) {
 161     next unless ($user =~ m/..../);
 162     add_user($user);
 163 }
 164
 165 if (defined $usertag) {
 166     my %select_ut = ();
 167     my ($u, $t) = split /:/, $usertag, 2;
 168     Debbugs::User::read_usertags(\%select_ut, $u);
 169     unless (defined $t && $t ne "") {
 170         $t = join(",", keys(%select_ut));
 171     }
 172
 173     add_user($u);
 174     $tag = $t;
 175 }
 176
 177 my $Archived = $archive ? " Archived" : "";
 178
 179 my $this = "";
 180
 181 my %indexentry;
 182 my %strings = ();
 183
 184 $ENV{"TZ"} = 'UTC';
 185 tzset();
 186
 187 my $dtime = strftime "%a, %e %b %Y %T UTC", localtime;
 188 my $tail_html = $debbugs::gHTMLTail;
 189 $tail_html = $debbugs::gHTMLTail;
 190 $tail_html =~ s/SUBSTITUTE_DTIME/$dtime/;
 191
 192 set_option("repeatmerged", $repeatmerged);
 193 set_option("archive", $archive);
 194 set_option("include", $include);
 195 set_option("exclude", $exclude);
 196 set_option("pend-exc", $pend_exc);
 197 set_option("pend-inc", $pend_inc);
 198 set_option("sev-exc", $sev_exc);
 199 set_option("sev-inc", $sev_inc);
 200 set_option("maxdays", $maxdays);
 201 set_option("mindays", $mindays);
 202 set_option("version", $version);
 203 set_option("dist", $dist);
 204 set_option("arch", $arch);
 205 set_option("use-bug-idx", defined($param{'use-bug-idx'}) ? $param{'use-bug-idx'} : 0);
 206 set_option("show_list_header", $show_list_header);
 207 set_option("show_list_footer", $show_list_footer);
 208
 209 sub add_user {
 210     my $ut = \%ut;
 211     my $u = shift;
 212
 213     my $user = Debbugs::User::get_user($u);
 214
 215     my %vis = map { $_, 1 } @{$user->{"visible_cats"}};
 216     for my $c (keys %{$user->{"categories"}}) {
 217         $cats{$c} = $user->{"categories"}->{$c};
 218         $hidden{$c} = 1 unless defined $vis{$c};
 219     }
 220
 221     for my $t (keys %{$user->{"tags"}}) {
 222         $ut->{$t} = [] unless defined $ut->{$t};
 223         push @{$ut->{$t}}, @{$user->{"tags"}->{$t}};
 224     }
 225
 226     %bugusertags = ();
 227     for my $t (keys %{$ut}) {
 228         for my $b (@{$ut->{$t}}) {
 229             $bugusertags{$b} = [] unless defined $bugusertags{$b};
 230             push @{$bugusertags{$b}}, $t;
 231         }
 232     }
 233     set_option("bugusertags", \%bugusertags);
 234 }
 235
 236 my $title;
 237 my @bugs;
 238 if (defined $pkg) {
 239   $title = "package $pkg";
 240   add_user("$pkg\@packages.debian.org");
 241   if (defined $version) {
 242     $title .= " (version $version)";
 243   } elsif (defined $dist) {
 244     $title .= " in $dist";
 245     my $verdesc = getversiondesc($pkg);
 246     $title .= " ($verdesc)" if defined $verdesc;
 247   }
 248   my @pkgs = split /,/, $pkg;
 249   @bugs = @{getbugs(sub {my %d=@_;
 250                          foreach my $try (splitpackages($d{"pkg"})) {
 251                            return 1 if grep($try eq $_, @pkgs);
 252                          }
 253                          return 0;
 254                         }, 'package', @pkgs)};
 255 } elsif (defined $src) {
 256   add_user("$src\@packages.debian.org");
 257   $title = "source $src";
 258   set_option('arch', 'source');
 259   if (defined $version) {
 260     $title .= " (version $version)";
 261   } elsif (defined $dist) {
 262     $title .= " in $dist";
 263     my $verdesc = getversiondesc($src);
 264     $title .= " ($verdesc)" if defined $verdesc;
 265   }
 266   my @pkgs = ();
 267   my @srcs = split /,/, $src;
 268   foreach my $try (@srcs) {
 269     push @pkgs, getsrcpkgs($try);
 270     push @pkgs, $try if ( !grep(/^\Q$try\E$/, @pkgs) );
 271   }
 272   @bugs = @{getbugs(sub {my %d=@_;
 273                          foreach my $try (splitpackages($d{"pkg"})) {
 274                            return 1 if grep($try eq $_, @pkgs);
 275                          }
 276                          return 0;
 277                         }, 'package', @pkgs)};
 278 } elsif (defined $maint) {
 279   my %maintainers = %{getmaintainers()};
 280   add_user($maint);
 281   $title = "maintainer $maint";
 282   $title .= " in $dist" if defined $dist;
 283   if ($maint eq "") {
 284     @bugs = @{getbugs(sub {my %d=@_;
 285                            foreach my $try (splitpackages($d{"pkg"})) {
 286                              return 1 if !getparsedaddrs($maintainers{$try});
 287                            }
 288                            return 0;
 289                           })};
 290   } else {
 291     my @maints = split /,/, $maint;
 292     my @pkgs = ();
 293     foreach my $try (@maints) {
 294       foreach my $p (keys %maintainers) {
 295         my @me = getparsedaddrs($maintainers{$p});
 296         push @pkgs, $p if grep { $_->address eq $try } @me;
 297       }
 298     }
 299     @bugs = @{getbugs(sub {my %d=@_;
 300                            foreach my $try (splitpackages($d{"pkg"})) {
 301                              my @me = getparsedaddrs($maintainers{$try});
 302                              return 1 if grep { $_->address eq $maint } @me;
 303                            }
 304                            return 0;
 305                           }, 'package', @pkgs)};
 306   }
 307 } elsif (defined $maintenc) {
 308   my %maintainers = %{getmaintainers()};
 309   $title = "encoded maintainer $maintenc";
 310   $title .= " in $dist" if defined $dist;
 311   @bugs = @{getbugs(sub {my %d=@_;
 312                          foreach my $try (splitpackages($d{"pkg"})) {
 313                            my @me = getparsedaddrs($maintainers{$try});
 314                            return 1 if grep {
 315                              maintencoded($_->address) eq $maintenc
 316                            } @me;
 317                          }
 318                          return 0;
 319                         })};
 320 } elsif (defined $submitter) {
 321   add_user($submitter);
 322   $title = "submitter $submitter";
 323   $title .= " in $dist" if defined $dist;
 324   my @submitters = split /,/, $submitter;
 325   @bugs = @{getbugs(sub {my %d=@_;
 326                          my @se = getparsedaddrs($d{"submitter"} || "");
 327                          foreach my $try (@submitters) {
 328                            return 1 if grep { $_->address eq $try } @se;
 329                          }
 330                         }, 'submitter-email', @submitters)};
 331 } elsif (defined($severity) && defined($status)) {
 332   $title = "$status $severity bugs";
 333   $title .= " in $dist" if defined $dist;
 334   my @severities = split /,/, $severity;
 335   my @statuses = split /,/, $status;
 336   @bugs = @{getbugs(sub {my %d=@_;
 337                        return (grep($d{"severity"} eq $_, @severities))
 338                          && (grep($d{"status"} eq $_, @statuses));
 339                      })};
 340 } elsif (defined($severity)) {
 341   $title = "$severity bugs";
 342   $title .= " in $dist" if defined $dist;
 343   my @severities = split /,/, $severity;
 344   @bugs = @{getbugs(sub {my %d=@_;
 345                        return (grep($d{"severity"} eq $_, @severities));
 346                      }, 'severity', @severities)};
 347 } elsif (defined($tag)) {
 348   $title = "bugs tagged $tag";
 349   $title .= " in $dist" if defined $dist;
 350   my @tags = split /,/, $tag;
 351   my %bugs = ();
 352   for my $t (@tags) {
 353       for my $b (@{$ut{$t}}) {
 354           $bugs{$b} = 1;
 355        }
 356   }
 357   @bugs = @{getbugs(sub {my %d = @_;
 358                          return 1 if $bugs{$d{"bug"}};
 359                          my %tags = map { $_ => 1 } split ' ', $d{"tags"};
 360                          return grep(exists $tags{$_}, @tags);
 361                         })};
 362 }
 363 $title = htmlsanit($title);
 364
 365 my @names; my @prior; my @title; my @order;
 366 determine_ordering();
 367
 368 # strip out duplicate bugs
 369 my %bugs;
 370 @bugs{@bugs} = @bugs;
 371 @bugs = keys %bugs;
 372
 373 my $result = pkg_htmlizebugs(\@bugs);
 374
 375 print "Content-Type: text/html; charset=utf-8\n\n";
 376
 377 print "<!DOCTYPE HTML PUBLIC \"-//W3C//DTD HTML 4.01 Transitional//EN\">\n";
 378 print "<HTML><HEAD>\n" .
 379     "<TITLE>$debbugs::gProject$Archived $debbugs::gBug report logs: $title</TITLE>\n" .
 380     '<link rel="stylesheet" href="/css/bugs.css" type="text/css">' .
 381     "</HEAD>\n" .
 382     '<BODY onload="pagemain();">' .
 383     "\n";
 384 print "<H1>" . "$debbugs::gProject$Archived $debbugs::gBug report logs: $title" .
 385       "</H1>\n";
 386
 387 my $showresult = 1;
 388
 389 if (defined $pkg || defined $src) {
 390     my $showpkg = htmlsanit((defined $pkg) ? $pkg : "source package $src");
 391     my %maintainers = %{getmaintainers()};
 392     my $maint = $pkg ? $maintainers{$pkg} : $maintainers{$src} ? $maintainers{$src} : undef;
 393     if (defined $maint) {
 394         print '<p>';
 395         print htmlmaintlinks(sub { $_[0] == 1 ? "Maintainer for $showpkg is "
 396                                               : "Maintainers for $showpkg are "
 397                                  },
 398                              $maint);
 399         print ".</p>\n";
 400     } else {
 401         print "<p>No maintainer for $showpkg. Please do not report new bugs against this package.</p>\n";
 402     }
 403     if (defined $maint or @bugs) {
 404         my %pkgsrc = %{getpkgsrc()};
 405         my $srcforpkg;
 406         if (defined $pkg) {
 407             $srcforpkg = $pkgsrc{$pkg};
 408             defined $srcforpkg or $srcforpkg = $pkg;
 409         }
 410         my @pkgs = getsrcpkgs($pkg ? $srcforpkg : $src);
 411         undef $srcforpkg unless @pkgs;
 412         @pkgs = grep( !/^\Q$pkg\E$/, @pkgs ) if ( $pkg );
 413         if ( @pkgs ) {
 414             @pkgs = sort @pkgs;
 415             if ($pkg) {
 416                     print "<p>You may want to refer to the following packages that are part of the same source:\n";
 417             } else {
 418                     print "<p>You may want to refer to the following individual bug pages:\n";
 419             }
 420             push @pkgs, $src if ( $src && !grep(/^\Q$src\E$/, @pkgs) );
 421             print join( ", ", map( "<A href=\"" . pkgurl($_) . "\">$_</A>", @pkgs ) );
 422             print ".\n";
 423         }
 424         my @references;
 425         my $pseudodesc = getpseudodesc();
 426         if ($pkg and defined($pseudodesc) and exists($pseudodesc->{$pkg})) {
 427             push @references, "to the <a href=\"http://${debbugs::gWebDomain}/pseudo-packages${debbugs::gHTMLSuffix}\">list of other pseudo-packages</a>";
 428         } else {
 429             if ($pkg and defined $debbugs::gPackagePages) {
 430                 push @references, sprintf "to the <a href=\"%s\">%s package page</a>", urlsanit("http://${debbugs::gPackagePages}/$pkg"), htmlsanit("$pkg");
 431             }
 432             if (defined $debbugs::gSubscriptionDomain) {
 433                 my $ptslink = $pkg ? $srcforpkg : $src;
 434                 push @references, "to the <a href=\"http://$debbugs::gSubscriptionDomain/$ptslink\">Package Tracking System</a>";
 435             }
 436             # Only output this if the source listing is non-trivial.
 437             if ($pkg and $srcforpkg and (@pkgs or $pkg ne $srcforpkg)) {
 438                 push @references, sprintf "to the source package <a href=\"%s\">%s</a>'s bug page", srcurl($srcforpkg), htmlsanit($srcforpkg);
 439             }
 440         }
 441         if ($pkg) {
 442             set_option("archive", !$archive);
 443             push @references, sprintf "to the <a href=\"%s\">%s reports for %s</a>", pkgurl($pkg), ($archive ? "active" : "archived"), htmlsanit($pkg);
 444             set_option("archive", $archive);
 445         }
 446         if (@references) {
 447             $references[$#references] = "or $references[$#references]" if @references > 1;
 448             print "<p>You might like to refer ", join(", ", @references), ".</p>\n";
 449         }
 450         print "<p>If you find a bug not listed here, please\n";
 451         printf "<a href=\"%s\">report it</a>.</p>\n",
 452                urlsanit("http://${debbugs::gWebDomain}/Reporting${debbugs::gHTMLSuffix}");
 453     } else {
 454         print "<p>There is no record of the " .
 455               (defined($pkg) ? htmlsanit($pkg) . " package"
 456                              : htmlsanit($src) . " source package") .
 457               ", and no bugs have been filed against it.</p>";
 458         $showresult = 0;
 459     }
 460 } elsif (defined $maint || defined $maintenc) {
 461     print "<p>Note that maintainers may use different Maintainer fields for\n";
 462     print "different packages, so there may be other reports filed under\n";
 463     print "different addresses.\n";
 464 } elsif (defined $submitter) {
 465     print "<p>Note that people may use different email accounts for\n";
 466     print "different bugs, so there may be other reports filed under\n";
 467     print "different addresses.\n";
 468 }
 469
 470 print $result if $showresult;
 471
 472 print pkg_javascript() . "\n";
 473 print "<h2 class=\"outstanding\"><a class=\"options\" href=\"javascript:toggle(1)\">Options</a></h2>\n";
 474 print "<div id=\"a_1\">\n";
 475 printf "<form action=\"%s\" method=POST>\n", myurl();
 476
 477 print "<table class=\"forms\">\n";
 478
 479 my ($checked_any, $checked_sui, $checked_ver) = ("", "", "");
 480 if (defined $dist) {
 481   $checked_sui = "CHECKED";
 482 } elsif (defined $version) {
 483   $checked_ver = "CHECKED";
 484 } else {
 485   $checked_any = "CHECKED";
 486 }
 487
 488 print "<tr><td>Show bugs applicable to</td>\n";
 489 print "    <td><input id=\"b_1_1\" name=vt value=none type=radio onchange=\"enable(1);\" $checked_any>anything</td></tr>\n";
 490 print "<tr><td></td>";
 491 print "    <td><input id=\"b_1_2\" name=vt value=bysuite type=radio onchange=\"enable(1);\" $checked_sui>" . pkg_htmlselectsuite(1,2,1) . " for " . pkg_htmlselectarch(1,2,2) . "</td></tr>\n";
 492
 493 if (defined $pkg) {
 494     my $v = htmlsanit($version) || "";
 495     my $pkgsane = htmlsanit($pkg);
 496     print "<tr><td></td>";
 497     print "    <td><input id=\"b_1_3\" name=vt value=bypkg type=radio onchange=\"enable(1);\" $checked_ver>$pkgsane version <input id=\"b_1_3_1\" name=version value=\"$v\"></td></tr>\n";
 498 } elsif (defined $src) {
 499     my $v = htmlsanit($version) || "";
 500     my $srcsane = htmlsanit($src);
 501     print "<tr><td></td>";
 502     print "    <td><input name=vt value=bysrc type=radio onchange=\"enable(1);\" $checked_ver>$srcsane version <input id=\"b_1_3_1\" name=version value=\"$v\"></td></tr>\n";
 503 }
 504 print "<tr><td>&nbsp;</td></tr>\n";
 505
 506 my $includetags = htmlsanit(join(" ", grep { !m/^subj:/i } split /[\s,]+/, $include));
 507 my $excludetags = htmlsanit(join(" ", grep { !m/^subj:/i } split /[\s,]+/, $exclude));
 508 my $includesubj = htmlsanit(join(" ", map { s/^subj://i; $_ } grep { m/^subj:/i } split /[\s,]+/, $include));
 509 my $excludesubj = htmlsanit(join(" ", map { s/^subj://i; $_ } grep { m/^subj:/i } split /[\s,]+/, $exclude));
 510 my $vismindays = ($mindays == 0 ? "" : $mindays);
 511 my $vismaxdays = ($maxdays == -1 ? "" : $maxdays);
 512
 513 my $sel_rmy = ($repeatmerged ? " selected" : "");
 514 my $sel_rmn = ($repeatmerged ? "" : " selected");
 515 my $sel_ordraw = ($ordering eq "raw" ? " selected" : "");
 516 my $sel_ordold = ($ordering eq "oldview" ? " selected" : "");
 517 my $sel_ordnor = ($ordering eq "normal" ? " selected" : "");
 518
 519 my $chk_bugrev = ($bug_rev ? " checked" : "");
 520 my $chk_pendrev = ($pend_rev ? " checked" : "");
 521 my $chk_sevrev = ($sev_rev ? " checked" : "");
 522
 523 print <<EOF;
 524 <tr><td>Only include bugs tagged with </td><td><input name=include value="$includetags"> or that have <input name=includesubj value="$includesubj"> in their subject</td></tr>
 525 <tr><td>Exclude bugs tagged with </td><td><input name=exclude value="$excludetags"> or that have <input name=excludesubj value="$excludesubj"> in their subject</td></tr>
 526 <tr><td>Only show bugs older than</td><td><input name=mindays value="$vismindays" size=5> days, and younger than <input name=maxdays value="$vismaxdays" size=5> days</td></tr>
 527
 528 <tr><td>&nbsp;</td></tr>
 529
 530 </td></tr>
 531 <tr><td>Merged bugs should be</td><td>
 532 <select name=repeatmerged>
 533 <option value=yes$sel_rmy>displayed separately</option>
 534 <option value=no$sel_rmn>combined</option>
 535 </select>
 536 <tr><td>Categorise bugs by</td><td>
 537 <select name=ordering>
 538 <option value=raw$sel_ordraw>bug number only</option>
 539 <option value=old$sel_ordold>status and severity</option>
 540 <option value=normal$sel_ordnor>status, severity and classification</option>
 541 EOF
 542
 543 {
 544 my $any = 0;
 545 my $o = $param{"ordering"} || "";
 546 for my $n (keys %cats) {
 547     next if ($n eq "normal" || $n eq "oldview");
 548     next if defined $hidden{$n};
 549     unless ($any) {
 550         $any = 1;
 551         print "<option disabled>------</option>\n";
 552     }
 553     my @names = map { ref($_) eq "HASH" ? $_->{"nam"} : $_ } @{$cats{$n}};
 554     my $name;
 555     if (@names == 1) { $name = $names[0]; }
 556     else { $name = " and " . pop(@names); $name = join(", ", @names) . $name; }
 557
 558     printf "<option value=\"%s\"%s>%s</option>\n",
 559         $n, ($o eq $n ? " selected" : ""), $name;
 560 }
 561 }
 562
 563 print "</select></td></tr>\n";
 564
 565 printf "<tr><td>Order bugs by</td><td>%s</td></tr>\n",
 566     pkg_htmlselectyesno("pend-rev", "outstanding bugs first", "done bugs first", $pend_rev);
 567 printf "<tr><td></td><td>%s</td></tr>\n",
 568     pkg_htmlselectyesno("sev-rev", "highest severity first", "lowest severity first", $sev_rev);
 569 printf "<tr><td></td><td>%s</td></tr>\n",
 570     pkg_htmlselectyesno("bug-rev", "oldest bugs first", "newest bugs first", $bug_rev);
 571
 572 print <<EOF;
 573 <tr><td>&nbsp;</td></tr>
 574 <tr><td colspan=2><input value="Reload page" type="submit"> with new settings</td></tr>
 575 EOF
 576
 577 print "</table></form></div>\n";
 578
 579 print "<hr>\n";
 580 print "<p>$tail_html";
 581
 582 print "</body></html>\n";
 583
 584 sub pkg_htmlindexentrystatus {
 585     my $s = shift;
 586     my %status = %{$s};
 587
 588     my $result = "";
 589
 590     my $showseverity;
 591     if  ($status{severity} eq 'normal') {
 592         $showseverity = '';
 593     } elsif (isstrongseverity($status{severity})) {
 594         $showseverity = "Severity: <em class=\"severity\">$status{severity}</em>;\n";
 595     } else {
 596         $showseverity = "Severity: <em>$status{severity}</em>;\n";
 597     }
 598
 599     $result .= pkg_htmlpackagelinks($status{"package"}, 1);
 600
 601     my $showversions = '';
 602     if (@{$status{found_versions}}) {
 603         my @found = @{$status{found_versions}};
 604         local $_;
 605         s{/}{ } foreach @found;
 606         $showversions .= join ', ', map htmlsanit($_), @found;
 607     }
 608     if (@{$status{fixed_versions}}) {
 609         $showversions .= '; ' if length $showversions;
 610         $showversions .= '<strong>fixed</strong>: ';
 611         my @fixed = @{$status{fixed_versions}};
 612         local $_;
 613         s{/}{ } foreach @fixed;
 614         $showversions .= join ', ', map htmlsanit($_), @fixed;
 615     }
 616     $result .= " ($showversions)" if length $showversions;
 617     $result .= ";\n";
 618
 619     $result .= $showseverity;
 620     $result .= pkg_htmladdresslinks("Reported by: ", \&submitterurl,
 621                                 $status{originator});
 622     $result .= ";\nOwned by: " . htmlsanit($status{owner})
 623                if length $status{owner};
 624     $result .= ";\nTags: <strong>"
 625                  . htmlsanit(join(", ", sort(split(/\s+/, $status{tags}))))
 626                  . "</strong>"
 627                        if (length($status{tags}));
 628
 629     $result .= buglinklist(";\nMerged with ", ", ",
 630         split(/ /,$status{mergedwith}));
 631     $result .= buglinklist(";\nBlocked by ", ", ",
 632         split(/ /,$status{blockedby}));
 633     $result .= buglinklist(";\nBlocks ", ", ",
 634         split(/ /,$status{blocks}));
 635
 636     my $days = 0;
 637     if (length($status{done})) {
 638         $result .= "<br><strong>Done:</strong> " . htmlsanit($status{done});
 639         $days = ceil($debbugs::gRemoveAge - -M buglog($status{id}));
 640         if ($days >= 0) {
 641             $result .= ";\n<strong>Will be archived" . ( $days == 0 ? " today" : $days == 1 ? " in $days day" : " in $days days" ) . "</strong>";
 642         } else {
 643             $result .= ";\n<strong>Archived</strong>";
 644         }
 645     }
 646
 647     unless (length($status{done})) {
 648         if (length($status{forwarded})) {
 649             $result .= ";\n<strong>Forwarded</strong> to "
 650                        . join(', ',
 651                               map {maybelink($_)}
 652                               split /,\s*/,$status{forwarded}
 653                              );
 654         }
 655         my $daysold = int((time - $status{date}) / 86400);   # seconds to days
 656         if ($daysold >= 7) {
 657             my $font = "";
 658             my $efont = "";
 659             $font = "em" if ($daysold > 30);
 660             $font = "strong" if ($daysold > 60);
 661             $efont = "</$font>" if ($font);
 662             $font = "<$font>" if ($font);
 663
 664             my $yearsold = int($daysold / 365);
 665             $daysold -= $yearsold * 365;
 666
 667             $result .= ";\n $font";
 668             my @age;
 669             push @age, "1 year" if ($yearsold == 1);
 670             push @age, "$yearsold years" if ($yearsold > 1);
 671             push @age, "1 day" if ($daysold == 1);
 672             push @age, "$daysold days" if ($daysold > 1);
 673             $result .= join(" and ", @age);
 674             $result .= " old$efont";
 675         }
 676     }
 677
 678     $result .= ".";
 679
 680     return $result;
 681 }
 682
 683
 684 sub pkg_htmlizebugs {
 685     $b = $_[0];
 686     my @bugs = @$b;
 687
 688     my @status = ();
 689     my %count;
 690     my $header = '';
 691     my $footer = "<h2 class=\"outstanding\">Summary</h2>\n";
 692
 693     my @dummy = ($debbugs::gRemoveAge); #, @debbugs::gSeverityList, @debbugs::gSeverityDisplay);  #, $debbugs::gHTMLExpireNote);
 694
 695     if (@bugs == 0) {
 696         return "<HR><H2>No reports found!</H2></HR>\n";
 697     }
 698
 699     if ( $bug_rev ) {
 700         @bugs = sort {$b<=>$a} @bugs;
 701     } else {
 702         @bugs = sort {$a<=>$b} @bugs;
 703     }
 704     my %seenmerged;
 705
 706     my %common = (
 707         'show_list_header' => 1,
 708         'show_list_footer' => 1,
 709     );
 710
 711     my %section = ();
 712
 713     foreach my $bug (@bugs) {
 714         my %status = %{getbugstatus($bug)};
 715         next unless %status;
 716         next if bugfilter($bug, %status);
 717
 718         my $html = sprintf "<li><a href=\"%s\">#%d: %s</a>\n<br>",
 719             bugurl($bug), $bug, htmlsanit($status{subject});
 720         $html .= pkg_htmlindexentrystatus(\%status) . "\n";
 721
 722         my $key = "";
 723         for my $i (0..$#prior) {
 724             my $v = get_bug_order_index($prior[$i], \%status);
 725             $count{"g_${i}_${v}"}++;
 726             $key .= "_$v";
 727         }
 728         $section{$key} .= $html;
 729         $count{"_$key"}++;
 730
 731         push @status, [ $bug, \%status, $html ];
 732     }
 733
 734     my $result = "";
 735     if ($ordering eq "raw") {
 736         $result .= "<UL class=\"bugs\">\n" . join("", map( { $_->[ 2 ] } @status ) ) . "</UL>\n";
 737     } else {
 738         $header .= "<ul>\n<div class=\"msgreceived\">\n";
 739         my @keys_in_order = ("");
 740         for my $o (@order) {
 741             push @keys_in_order, "X";
 742             while ((my $k = shift @keys_in_order) ne "X") {
 743                 for my $k2 (@{$o}) {
 744                     push @keys_in_order, "${k}_${k2}";
 745                 }
 746             }
 747         }
 748         for ( my $i = 0; $i <= $#keys_in_order; $i++ ) {
 749             my $order = $keys_in_order[ $i ];
 750             next unless defined $section{$order};
 751             my @ttl = split /_/, $order; shift @ttl;
 752             my $title = $title[0]->[$ttl[0]] . " bugs";
 753             if ($#ttl > 0) {
 754                 $title .= " -- ";
 755                 $title .= join("; ", grep {($_ || "") ne ""}
 756                         map { $title[$_]->[$ttl[$_]] } 1..$#ttl);
 757             }
 758             $title = htmlsanit($title);
 759
 760             my $count = $count{"_$order"};
 761             my $bugs = $count == 1 ? "bug" : "bugs";
 762
 763             $header .= "<li><a href=\"#$order\">$title</a> ($count $bugs)</li>\n";
 764             if ($common{show_list_header}) {
 765                 my $count = $count{"_$order"};
 766                 my $bugs = $count == 1 ? "bug" : "bugs";
 767                 $result .= "<H2 CLASS=\"outstanding\"><a name=\"$order\"></a>$title ($count $bugs)</H2>\n";
 768             } else {
 769                 $result .= "<H2 CLASS=\"outstanding\">$title</H2>\n";
 770             }
 771             $result .= "<div class=\"msgreceived\">\n<UL class=\"bugs\">\n";
 772             $result .= "\n\n\n\n";
 773             $result .= $section{$order};
 774             $result .= "\n\n\n\n";
 775             $result .= "</UL>\n</div>\n";
 776         }
 777         $header .= "</ul></div>\n";
 778
 779         $footer .= "<ul>\n<div class=\"msgreceived\">";
 780         for my $i (0..$#prior) {
 781             my $local_result = '';
 782             foreach my $key ( @{$order[$i]} ) {
 783                 my $count = $count{"g_${i}_$key"};
 784                 next if !$count or !$title[$i]->[$key];
 785                 $local_result .= "<li>$count $title[$i]->[$key]</li>\n";
 786             }
 787             if ( $local_result ) {
 788                 $footer .= "<li>$names[$i]<ul>\n$local_result</ul></li>\n";
 789             }
 790         }
 791         $footer .= "</div></ul>\n";
 792     }
 793
 794     $result = $header . $result if ( $common{show_list_header} );
 795     $result .= $footer if ( $common{show_list_footer} );
 796     return $result;
 797 }
 798
 799 sub pkg_htmlpackagelinks {
 800     my $pkgs = shift;
 801     return unless defined $pkgs and $pkgs ne '';
 802     my $strong = shift;
 803     my @pkglist = splitpackages($pkgs);
 804
 805     $strong = 0;
 806     my $openstrong  = $strong ? '<strong>' : '';
 807     my $closestrong = $strong ? '</strong>' : '';
 808
 809     return 'Package' . (@pkglist > 1 ? 's' : '') . ': ' .
 810            join(', ',
 811                 map {
 812                     '<a class="submitter" href="' . pkgurl($_) . '">' .
 813                     $openstrong . htmlsanit($_) . $closestrong . '</a>'
 814                 } @pkglist
 815            );
 816 }
 817
 818 sub pkg_htmladdresslinks {
 819     my ($prefixfunc, $urlfunc, $addresses) = @_;
 820     if (defined $addresses and $addresses ne '') {
 821         my @addrs = getparsedaddrs($addresses);
 822         my $prefix = (ref $prefixfunc) ? $prefixfunc->(scalar @addrs)
 823                                        : $prefixfunc;
 824         return $prefix .
 825                join ', ', map { sprintf '<a class="submitter" href="%s">%s</a>',
 826                                         $urlfunc->($_->address),
 827                                         htmlsanit($_->format) || '(unknown)'
 828                               } @addrs;
 829     } else {
 830         my $prefix = (ref $prefixfunc) ? $prefixfunc->(1) : $prefixfunc;
 831         return sprintf '%s<a class="submitter" href="%s">(unknown)</a>', $prefix, $urlfunc->('');
 832     }
 833 }
 834
 835 sub pkg_javascript {
 836     return <<EOF ;
 837 <script type="text/javascript">
 838 <!--
 839 function pagemain() {
 840         toggle(1);
 841         toggle(2);
 842         enable(1);
 843 }
 844
 845 function setCookie(name, value, expires, path, domain, secure) {
 846   var curCookie = name + "=" + escape(value) +
 847       ((expires) ? "; expires=" + expires.toGMTString() : "") +
 848       ((path) ? "; path=" + path : "") +
 849       ((domain) ? "; domain=" + domain : "") +
 850       ((secure) ? "; secure" : "");
 851   document.cookie = curCookie;
 852 }
 853
 854 function save_cat_cookies() {
 855   var cat = document.categories.categorisation.value;
 856   var exp = new Date();
 857   exp.setTime(exp.getTime() + 10 * 365 * 24 * 60 * 60 * 1000);
 858   var oldexp = new Date();
 859   oldexp.setTime(oldexp.getTime() - 1 * 365 * 24 * 60 * 60 * 1000);
 860   var lev;
 861   var done = 0;
 862
 863   var u = document.getElementById("users");
 864   if (u != null) { u = u.value; }
 865   if (u == "") { u = null; }
 866   if (u != null) {
 867       setCookie("cat" + cat + "_users", u, exp, "/");
 868   } else {
 869       setCookie("cat" + cat + "_users", "", oldexp, "/");
 870   }
 871
 872   var bits = new Array("nam", "pri", "ttl", "ord");
 873   for (var i = 0; i < 4; i++) {
 874       for (var j = 0; j < bits.length; j++) {
 875           var e = document.getElementById(bits[j] + i);
 876           if (e) e = e.value;
 877           if (e == null) { e = ""; }
 878           if (j == 0 && e == "") { done = 1; }
 879           if (done || e == "") {
 880               setCookie("cat" + cat + "_" + bits[j] + i, "", oldexp, "/");
 881           } else {
 882               setCookie("cat" + cat + "_" + bits[j] + i, e, exp, "/");
 883           }
 884       }
 885   }
 886 }
 887
 888 function toggle(i) {
 889         var a = document.getElementById("a_" + i);
 890         if (a.style.display == "none") {
 891                 a.style.display = "";
 892         } else {
 893                 a.style.display = "none";
 894         }
 895 }
 896
 897 function enable(x) {
 898     for (var i = 1; ; i++) {
 899         var a = document.getElementById("b_" + x + "_" + i);
 900         if (a == null) break;
 901         var ischecked = a.checked;
 902         for (var j = 1; ; j++) {
 903             var b = document.getElementById("b_" + x + "_"+ i + "_" + j);
 904             if (b == null) break;
 905             if (ischecked) {
 906                 b.disabled = false;
 907             } else {
 908                 b.disabled = true;
 909             }
 910         }
 911     }
 912 }
 913 -->
 914 </script>
 915 EOF
 916 }
 917
 918 sub pkg_htmlselectyesno {
 919     my ($name, $n, $y, $default) = @_;
 920     return sprintf('<select name="%s"><option value=no%s>%s</option><option value=yes%s>%s</option></select>', $name, ($default ? "" : " selected"), $n, ($default ? " selected" : ""), $y);
 921 }
 922
 923 sub pkg_htmlselectsuite {
 924     my $id = sprintf "b_%d_%d_%d", $_[0], $_[1], $_[2];
 925     my @suites = ("stable", "testing", "unstable", "experimental");
 926     my %suiteaka = ("stable", "sarge", "testing", "etch", "unstable", "sid");
 927     my $defaultsuite = "unstable";
 928
 929     my $result = sprintf '<select name=dist id="%s">', $id;
 930     for my $s (@suites) {
 931         $result .= sprintf '<option value="%s"%s>%s%s</option>',
 932                 $s, ($defaultsuite eq $s ? " selected" : ""),
 933                 $s, (defined $suiteaka{$s} ? " (" . $suiteaka{$s} . ")" : "");
 934     }
 935     $result .= '</select>';
 936     return $result;
 937 }
 938
 939 sub pkg_htmlselectarch {
 940     my $id = sprintf "b_%d_%d_%d", $_[0], $_[1], $_[2];
 941     my @arches = qw(alpha amd64 arm hppa i386 ia64 m68k mips mipsel powerpc s390 sparc);
 942
 943     my $result = sprintf '<select name=arch id="%s">', $id;
 944     $result .= '<option value="any">any architecture</option>';
 945     for my $a (@arches) {
 946         $result .= sprintf '<option value="%s">%s</option>', $a, $a;
 947     }
 948     $result .= '</select>';
 949     return $result;
 950 }
 951
 952 sub myurl {
 953     return pkg_etc_url($pkg, "pkg", 0) if defined($pkg);
 954     return pkg_etc_url($src, "src", 0) if defined($src);
 955     return pkg_etc_url($maint, "maint", 0) if defined($maint);
 956     return pkg_etc_url($submitter, "submitter", 0) if defined($submitter);
 957     return pkg_etc_url($severity, "severity", 0) if defined($severity);
 958     return pkg_etc_url($tag, "tag", 0) if defined($tag);
 959 }
 960
 961 sub make_order_list {
 962     my $vfull = shift;
 963     my @x = ();
 964
 965     if ($vfull =~ m/^([^:]+):(.*)$/) {
 966         my $v = $1;
 967         for my $vv (split /,/, $2) {
 968             push @x, "$v=$vv";
 969         }
 970     } else {
 971         for my $v (split /,/, $vfull) {
 972             next unless $v =~ m/.=./;
 973             push @x, $v;
 974         }
 975     }
 976     push @x, "";  # catch all
 977     return @x;
 978 }
 979
 980 sub get_bug_order_index {
 981     my $order = shift;
 982     my $status = shift;
 983     my $pos = -1;
 984
 985     my %tags = ();
 986     %tags = map { $_, 1 } split / /, $status->{"tags"}
 987         if defined $status->{"tags"};
 988
 989     for my $el (@${order}) {
 990         $pos++;
 991         my $match = 1;
 992         for my $item (split /[+]/, $el) {
 993             my ($f, $v) = split /=/, $item, 2;
 994             next unless (defined $f and defined $v);
 995             my $isokay = 0;
 996             $isokay = 1 if (defined $status->{$f} and $v eq $status->{$f});
 997             $isokay = 1 if ($f eq "tag" && defined $tags{$v});
 998             unless ($isokay) {
 999                 $match = 0;
1000                 last;
1001             }
1002         }
1003         if ($match) {
1004             return $pos;
1005             last;
1006         }
1007     }
1008     return $pos + 1;
1009 }
1010
1011 sub buglinklist {
1012     my ($prefix, $infix, @els) = @_;
1013     my $sep = $prefix;
1014     my $r = "";
1015     for my $e (@els) {
1016         $r .= $sep."<A class=\"submitter\" href=\"" . bugurl($e) . "\">#$e</A>";
1017         $sep = $infix;
1018     }
1019     return $r;
1020 }
1021
1022
1023 # sets: my @names; my @prior; my @title; my @order;
1024
1025 sub determine_ordering {
1026     $cats{status}[0]{ord} = [ reverse @{$cats{status}[0]{ord}} ]
1027         if ($pend_rev);
1028     $cats{severity}[0]{ord} = [ reverse @{$cats{severity}[0]{ord}} ]
1029         if ($sev_rev);
1030
1031     if (defined $param{"pri0"}) {
1032         my @c = ();
1033         my $i = 0;
1034         while (defined $param{"pri$i"}) {
1035             my $h = {};
1036
1037             my $pri = $param{"pri$i"};
1038             if ($pri =~ m/^([^:]*):(.*)$/) {
1039               $h->{"nam"} = $1;  # overridden later if necesary
1040               $h->{"pri"} = [ map { "$1=$_" } (split /,/, $2) ];
1041             } else {
1042               $h->{"pri"} = [ split /,/, $pri ];
1043             }
1044
1045             $h->{"nam"} = $param{"nam$i"}
1046                 if (defined $param{"nam$i"});
1047             $h->{"ord"} = [ split /,/, $param{"ord$i"} ]
1048                 if (defined $param{"ord$i"});
1049             $h->{"ttl"} = [ split /,/, $param{"ttl$i"} ]
1050                 if (defined $param{"ttl$i"});
1051
1052             push @c, $h;
1053             $i++;
1054         }
1055         $cats{"_"} = [@c];
1056         $ordering = "_";
1057     }
1058
1059     $ordering = "normal" unless defined $cats{$ordering};
1060
1061     sub get_ordering {
1062         my @res;
1063         my $cats = shift;
1064         my $o = shift;
1065         for my $c (@{$cats->{$o}}) {
1066             if (ref($c) eq "HASH") {
1067                 push @res, $c;
1068             } else {
1069                 push @res, get_ordering($cats, $c);
1070             }
1071         }
1072         return @res;
1073     }
1074     my @cats = get_ordering(\%cats, $ordering);
1075
1076     sub toenglish {
1077         my $expr = shift;
1078         $expr =~ s/[+]/ and /g;
1079         $expr =~ s/[a-z]+=//g;
1080         return $expr;
1081     }
1082
1083     my $i = 0;
1084     for my $c (@cats) {
1085         $i++;
1086         push @prior, $c->{"pri"};
1087         push @names, ($c->{"nam"} || "Bug attribute #" . $i);
1088         if (defined $c->{"ord"}) {
1089             push @order, $c->{"ord"};
1090         } else {
1091             push @order, [ 0..$#{$prior[-1]} ];
1092         }
1093         my @t = @{ $c->{"ttl"} } if defined $c->{ttl};
1094         if (($#t+1) < $#{$prior[-1]}) {
1095              push @t, map { toenglish($prior[-1]->[$_]) } ($#t+1)..($#{$prior[-1]});
1096         }
1097         push @t, $c->{"def"} || "";
1098         push @title, [@t];
1099     }
1100 }