cgi/pkgreport.cgi

   1 #!/usr/bin/perl -wT
   2
   3 package debbugs;
   4
   5 use strict;
   6 use POSIX qw(strftime tzset nice);
   7
   8 #require '/usr/lib/debbugs/errorlib';
   9 require './common.pl';
  10
  11 require '/etc/debbugs/config';
  12 require '/etc/debbugs/text';
  13
  14 use vars qw($gPackagePages $gWebDomain);
  15
  16 if ($ENV{REQUEST_METHOD} eq 'HEAD') {
  17     print "Content-Type: text/html\n\n";
  18     exit 0;
  19 }
  20
  21 nice(5);
  22
  23 my %param = readparse();
  24
  25 my $repeatmerged = ($param{'repeatmerged'} || "yes") eq "yes";
  26 my $archive = ($param{'archive'} || "no") eq "yes";
  27 my $include = $param{'&include'} || $param{'include'} || "";
  28 my $exclude = $param{'&exclude'} || $param{'exclude'} || "";
  29 my $raw_sort = ($param{'raw'} || "no") eq "yes";
  30 my $bug_rev = ($param{'bug-rev'} || "no") eq "yes";
  31 my $pend_rev = ($param{'pend-rev'} || "no") eq "yes";
  32 my $sev_rev = ($param{'sev-rev'} || "no") eq "yes";
  33 my $pend_exc = $param{'&pend-exc'} || $param{'pend-exc'} || "";
  34 my $pend_inc = $param{'&pend-inc'} || $param{'pend-inc'} || "";
  35 my $sev_exc = $param{'&sev-exc'} || $param{'sev-exc'} || "";
  36 my $sev_inc = $param{'&sev-inc'} || $param{'sev-inc'} || "";
  37
  38 my ($pkg, $src, $maint, $maintenc, $submitter, $severity, $status, $tag);
  39
  40 my %which = (
  41         'pkg' => \$pkg,
  42         'src' => \$src,
  43         'maint' => \$maint,
  44         'maintenc' => \$maintenc,
  45         'submitter' => \$submitter,
  46         'severity' => \$severity,
  47         'tag' => \$tag,
  48         );
  49 my @allowedEmpty = ( 'maint' );
  50
  51 my $found;
  52 foreach ( keys %which ) {
  53         $status = $param{'status'} || 'open' if /^severity$/;
  54         if (($found = $param{$_})) {
  55                 ${ $which{$_} } = $found;
  56                 last;
  57         }
  58 }
  59 if (!$found && !$archive) {
  60         foreach ( @allowedEmpty ) {
  61                 if (exists($param{$_})) {
  62                         ${ $which{$_} } = '';
  63                         $found = 1;
  64                         last;
  65                 }
  66         }
  67 }
  68 if (!$found) {
  69         my $which;
  70         if (($which = $param{'which'})) {
  71                 if (grep( /^\Q$which\E$/, @allowedEmpty)) {
  72                         ${ $which{$which} } = $param{'data'};
  73                         $found = 1;
  74                 } elsif (($found = $param{'data'})) {
  75                         ${ $which{$which} } = $found if (exists($which{$which}));
  76                 }
  77         }
  78 }
  79 quitcgi("You have to choose something to select by") if (!$found);
  80
  81 my $Archived = $archive ? " Archived" : "";
  82
  83 my $this = "";
  84
  85 my %indexentry;
  86 my %strings = ();
  87
  88 $ENV{"TZ"} = 'UTC';
  89 tzset();
  90
  91 my $dtime = strftime "%a, %e %b %Y %T UTC", localtime;
  92 my $tail_html = $debbugs::gHTMLTail;
  93 $tail_html = $debbugs::gHTMLTail;
  94 $tail_html =~ s/SUBSTITUTE_DTIME/$dtime/;
  95
  96 set_option("repeatmerged", $repeatmerged);
  97 set_option("archive", $archive);
  98 set_option("include", $include);
  99 set_option("exclude", $exclude);
 100 set_option("raw", $raw_sort);
 101 set_option("bug-rev", $bug_rev);
 102 set_option("pend-rev", $pend_rev);
 103 set_option("sev-rev", $sev_rev);
 104 set_option("pend-exc", $pend_exc);
 105 set_option("pend-inc", $pend_inc);
 106 set_option("sev-exc", $sev_exc);
 107 set_option("sev-inc", $sev_inc);
 108
 109 my $title;
 110 my @bugs;
 111 if (defined $pkg) {
 112   $title = "package $pkg";
 113   my @pkgs = split /,/, $pkg;
 114   @bugs = @{getbugs(sub {my %d=@_;
 115                          foreach my $try (splitpackages($d{"pkg"})) {
 116                            return 1 if grep($try eq $_, @pkgs);
 117                          }
 118                          return 0;
 119                         }, 'package', @pkgs)};
 120 } elsif (defined $src) {
 121   $title = "source $src";
 122   my @pkgs = ();
 123   my @srcs = split /,/, $src;
 124   foreach my $try (@srcs) {
 125     push @pkgs, getsrcpkgs($try);
 126     push @pkgs, $try if ( !grep(/^\Q$try\E$/, @pkgs) );
 127   }
 128   @bugs = @{getbugs(sub {my %d=@_;
 129                          foreach my $try (splitpackages($d{"pkg"})) {
 130                            return 1 if grep($try eq $_, @pkgs);
 131                          }
 132                          return 0;
 133                         }, 'package', @pkgs)};
 134 } elsif (defined $maint) {
 135   my %maintainers = %{getmaintainers()};
 136   $title = "maintainer $maint";
 137   if ($maint eq "") {
 138     @bugs = @{getbugs(sub {my %d=@_;
 139                            foreach my $try (splitpackages($d{"pkg"})) {
 140                              return 1 if !getparsedaddrs($maintainers{$try});
 141                            }
 142                            return 0;
 143                           })};
 144   } else {
 145     my @maints = split /,/, $maint;
 146     my @pkgs = ();
 147     foreach my $try (@maints) {
 148       foreach my $p (keys %maintainers) {
 149         my @me = getparsedaddrs($maintainers{$p});
 150         push @pkgs, $p if grep { $_->address eq $try } @me;
 151       }
 152     }
 153     @bugs = @{getbugs(sub {my %d=@_;
 154                            foreach my $try (splitpackages($d{"pkg"})) {
 155                              my @me = getparsedaddrs($maintainers{$try});
 156                              return 1 if grep { $_->address eq $maint } @me;
 157                            }
 158                            return 0;
 159                           }, 'package', @pkgs)};
 160   }
 161 } elsif (defined $maintenc) {
 162   my %maintainers = %{getmaintainers()};
 163   $title = "encoded maintainer $maintenc";
 164   @bugs = @{getbugs(sub {my %d=@_;
 165                          foreach my $try (splitpackages($d{"pkg"})) {
 166                            my @me = getparsedaddrs($maintainers{$try});
 167                            return 1 if grep {
 168                              maintencoded($_->address) eq $maintenc
 169                            } @me;
 170                          }
 171                          return 0;
 172                         })};
 173 } elsif (defined $submitter) {
 174   $title = "submitter $submitter";
 175   my @submitters = split /,/, $submitter;
 176   @bugs = @{getbugs(sub {my %d=@_; my $se;
 177                        ($se = $d{"submitter"} || "") =~ s/\s*\(.*\)\s*//;
 178                        $se = $1 if ($se =~ m/<(.*)>/);
 179                        return 1 if grep($se eq $_, @submitters);
 180                      }, 'submitter-email', @submitters)};
 181 } elsif (defined($severity) && defined($status)) {
 182   $title = "$status $severity bugs";
 183   my @severities = split /,/, $severity;
 184   my @statuses = split /,/, $status;
 185   @bugs = @{getbugs(sub {my %d=@_;
 186                        return (grep($d{"severity"} eq $_, @severities))
 187                          && (grep($d{"status"} eq $_, @statuses));
 188                      })};
 189 } elsif (defined($severity)) {
 190   $title = "$severity bugs";
 191   my @severities = split /,/, $severity;
 192   @bugs = @{getbugs(sub {my %d=@_;
 193                        return (grep($d{"severity"} eq $_, @severities));
 194                      }, 'severity', @severities)};
 195 } elsif (defined($tag)) {
 196   $title = "bugs tagged $tag";
 197   my @tags = split /,/, $tag;
 198   @bugs = @{getbugs(sub {my %d = @_;
 199                          my %tags = map { $_ => 1 } split ' ', $d{"tags"};
 200                          return grep(exists $tags{$_}, @tags);
 201                         })};
 202 }
 203
 204 my $result = htmlizebugs(\@bugs);
 205
 206 print "Content-Type: text/html\n\n";
 207
 208 print "<!DOCTYPE HTML PUBLIC \"-//W3C//DTD HTML 4.01 Transitional//EN\">\n";
 209 print "<HTML><HEAD>\n" .
 210     "<TITLE>$debbugs::gProject$Archived $debbugs::gBug report logs: $title</TITLE>\n" .
 211     "</HEAD>\n" .
 212     '<BODY TEXT="#000000" BGCOLOR="#FFFFFF" LINK="#0000FF" VLINK="#800080">' .
 213     "\n";
 214 print "<H1>" . "$debbugs::gProject$Archived $debbugs::gBug report logs: $title" .
 215       "</H1>\n";
 216
 217 my $showresult = 1;
 218
 219 if (defined $pkg || defined $src) {
 220     my %maintainers = %{getmaintainers()};
 221     my $maint = $pkg ? $maintainers{$pkg} : $maintainers{$src} ? $maintainers{$src} : undef;
 222     if (defined $maint) {
 223         print '<p>';
 224         my $showpkg = (defined $pkg) ? $pkg : "source package $src";
 225         print htmlmaintlinks(sub { $_[0] == 1 ? "Maintainer for $showpkg is "
 226                                               : "Maintainers for $showpkg are "
 227                                  },
 228                              $maint);
 229         print ".</p>\n";
 230     }
 231     if (defined $maint or @bugs) {
 232         my %pkgsrc = %{getpkgsrc()};
 233         my $srcforpkg;
 234         if (defined $pkg) {
 235             $srcforpkg = $pkgsrc{$pkg};
 236             defined $srcforpkg or $srcforpkg = $pkg;
 237         }
 238         my @pkgs = getsrcpkgs($pkg ? $srcforpkg : $src);
 239         undef $srcforpkg unless @pkgs;
 240         @pkgs = grep( !/^\Q$pkg\E$/, @pkgs ) if ( $pkg );
 241         if ( @pkgs ) {
 242             @pkgs = sort @pkgs;
 243             if ($pkg) {
 244                     print "You may want to refer to the following packages that are part of the same source:<br>\n";
 245             } else {
 246                     print "You may want to refer to the following individual bug pages:<br>\n";
 247             }
 248             push @pkgs, $src if ( $src && !grep(/^\Q$src\E$/, @pkgs) );
 249             print join( ", ", map( "<A href=\"" . pkgurl($_) . "\">$_</A>", @pkgs ) );
 250             print ".\n";
 251         }
 252         if ($pkg) {
 253             my @references;
 254             my $pseudodesc = getpseudodesc();
 255             if (defined($pseudodesc) and exists($pseudodesc->{$pkg})) {
 256                 push @references, "to the <a href=\"http://${debbugs::gWebDomain}/pseudo-packages${debbugs::gHTMLSuffix}\">list of other pseudo-packages</a>";
 257             } else {
 258                 push @references, sprintf "to the <a href=\"%s\">%s package page</a>", urlsanit("http://${debbugs::gPackagePages}/$pkg"), htmlsanit("$pkg");
 259             }
 260             if ($srcforpkg) {
 261                 if (defined $debbugs::gSubscriptionDomain) {
 262                     push @references, "to the <a href=\"http://$debbugs::gSubscriptionDomain/$srcforpkg\">Package Tracking System</a>";
 263                 }
 264                 # Only output this if the source listing is non-trivial.
 265                 if (@pkgs or $pkg ne $srcforpkg) {
 266                     push @references, sprintf "to the source package <a href=\"%s\">%s</a>'s bug page", srcurl($srcforpkg), htmlsanit($srcforpkg);
 267                 }
 268             }
 269             if (@references) {
 270                 $references[$#references] = "or $references[$#references]" if @references > 1;
 271                 print "<p>You might like to refer ", join(", ", @references), ".</p>\n";
 272             }
 273         }
 274         print "<p>If you find a bug not listed here, please\n";
 275         printf "<a href=\"%s\">report it</a>.</p>\n",
 276                urlsanit("http://${debbugs::gWebDomain}/Reporting${debbugs::gHTMLSuffix}");
 277     } else {
 278         print "<p>There is no record of the " .
 279               (defined($pkg) ? htmlsanit($pkg) . " package"
 280                              : htmlsanit($src) . " source package") .
 281               ", and no bugs have been filed against it.</p>";
 282         $showresult = 0;
 283     }
 284 } elsif (defined $maint || defined $maintenc) {
 285     print "<p>Note that maintainers may use different Maintainer fields for\n";
 286     print "different packages, so there may be other reports filed under\n";
 287     print "different addresses.\n";
 288 } elsif (defined $submitter) {
 289     print "<p>Note that people may use different email accounts for\n";
 290     print "different bugs, so there may be other reports filed under\n";
 291     print "different addresses.\n";
 292 }
 293
 294 print $result if $showresult;
 295
 296 print "<hr>\n";
 297 print "$tail_html";
 298
 299 print "</body></html>\n";