cgi/common.pl

   1 #!/usr/bin/perl -w
   2
   3 use DB_File;
   4 use Fcntl qw/O_RDONLY/;
   5 use Mail::Address;
   6 use MLDBM qw/DB_File/;
   7 use POSIX qw/ceil/;
   8
   9 $config_path = '/etc/debbugs';
  10 $lib_path = '/usr/lib/debbugs';
  11 require "$lib_path/errorlib";
  12
  13 use Debbugs::Versions;
  14 use Debbugs::MIME qw(decode_rfc1522);
  15
  16 $MLDBM::RemoveTaint = 1;
  17
  18 my $common_archive = 0;
  19 my $common_repeatmerged = 1;
  20 my %common_include = ();
  21 my %common_exclude = ();
  22 my $common_raw_sort = 0;
  23 my $common_bug_reverse = 0;
  24
  25 my %common_reverse = (
  26     'pending' => 0,
  27     'severity' => 0,
  28 );
  29 my %common = (
  30     'show_list_header' => 1,
  31     'show_list_footer' => 1,
  32 );
  33
  34 sub exact_field_match {
  35     my ($field, $values, $status) = @_;
  36     my @values = @$values;
  37     my @ret = grep {$_ eq $status->{$field} } @values;
  38     $#ret != -1;
  39 }
  40 sub contains_field_match {
  41     my ($field, $values, $status) = @_;
  42     foreach my $data (@$values) {
  43         return 1 if (index($status->{$field}, $data) > -1);
  44     }
  45     return 0;
  46 }
  47
  48 sub detect_user_agent {
  49     my $userAgent = $ENV{HTTP_USER_AGENT};
  50     return { 'name' => 'unknown' } unless defined $userAgent;
  51     return { 'name' => 'links' } if ( $userAgent =~ m,^ELinks,);
  52     return { 'name' => 'lynx' } if ( $userAgent =~ m,^Lynx,);
  53     return { 'name' => 'wget' } if ( $userAgent =~ m,^Wget,);
  54     return { 'name' => 'gecko' } if ( $userAgent =~ m,^Mozilla.* Gecko/,);
  55     return { 'name' => 'ie' } if ( $userAgent =~ m,^.*MSIE.*,);
  56     return { 'name' => 'unknown' };
  57 }
  58
  59 my %field_match = (
  60     'subject' => \&contains_field_match,
  61     'tags' => sub {
  62         my ($field, $values, $status) = @_;
  63         my %values = map {$_=>1} @$values;
  64         foreach my $t (split /\s+/, $status->{$field}) {
  65             return 1 if (defined $values{$t});
  66         }
  67         return 0;
  68     },
  69     'severity' => \&exact_field_match,
  70     'pending' => \&exact_field_match,
  71     'originator' => \%contains_field_match,
  72     'forwarded' => \%contains_field_match,
  73     'owner' => \%contains_field_match,
  74 );
  75 my @common_grouping = ( 'severity', 'pending' );
  76 my %common_grouping_order = (
  77     'pending' => [ qw( pending forwarded pending-fixed fixed done absent ) ],
  78     'severity' => \@debbugs::gSeverityList,
  79 );
  80 my %common_grouping_display = (
  81     'pending' => 'Status',
  82     'severity' => 'Severity',
  83 );
  84 my %common_headers = (
  85     'pending' => {
  86         "pending"       => "outstanding",
  87         "pending-fixed" => "pending upload",
  88         "fixed"         => "fixed in NMU",
  89         "done"          => "resolved",
  90         "forwarded"     => "forwarded to upstream software authors",
  91         "absent"        => "not applicable to this version",
  92     },
  93     'severity' => \%debbugs::gSeverityDisplay,
  94 );
  95
  96 my $common_version;
  97 my $common_dist;
  98 my $common_arch;
  99
 100 my $debug = 0;
 101
 102 sub array_option($) {
 103     my ($val) = @_;
 104     my @vals;
 105     @vals = ( $val ) if (ref($val) eq "" && $val );
 106     @vals = ( $$val ) if (ref($val) eq "SCALAR" && $$val );
 107     @vals = @{$val} if (ref($val) eq "ARRAY" );
 108     return @vals;
 109 }
 110
 111 sub filter_include_exclude($\%) {
 112     my ($val, $filter_map) = @_;
 113     my @vals = array_option($val);
 114     my @data = map {
 115         if (/^([^:]*):(.*)$/) { if ($1 eq 'subj') { ['subject', $2]; } else { [$1, $2] } } else { ['tags', $_] }
 116     } split /[\s,]+/, join ',', @vals;
 117     foreach my $data (@data) {
 118         &quitcgi("Invalid filter key: '$data->[0]'") if (!exists($field_match{$data->[0]}));
 119         push @{$filter_map->{$data->[0]}}, $data->[1];
 120     }
 121 }
 122
 123 sub filter_option($$\%) {
 124     my ($key, $val, $filter_map) = @_;
 125     my @vals = array_option($val);
 126     foreach $val (@vals) {
 127         push @{$filter_map->{$key}}, $val;
 128     }
 129 }
 130
 131 sub set_option {
 132     my ($opt, $val) = @_;
 133     if ($opt =~ m/^show_list_(foot|head)er$/) { $common{$opt} = $val; }
 134     if ($opt eq "archive") { $common_archive = $val; }
 135     if ($opt eq "repeatmerged") { $common_repeatmerged = $val; }
 136     if ($opt eq "exclude") {
 137         filter_include_exclude($val, %common_exclude);
 138     }
 139     if ($opt eq "include") {
 140         filter_include_exclude($val, %common_include);
 141     }
 142     if ($opt eq "raw") { $common_raw_sort = $val; }
 143     if ($opt eq "bug-rev") { $common_bug_reverse = $val; }
 144     if ($opt eq "pend-rev") { $common_reverse{pending} = $val; }
 145     if ($opt eq "sev-rev") { $common_reverse{severity} = $val; }
 146     if ($opt eq "pend-exc") {
 147         filter_option('pending', $val, %common_exclude);
 148     }
 149     if ($opt eq "pend-inc") {
 150         filter_option('pending', $val, %common_include);
 151     }
 152     if ($opt eq "sev-exc") {
 153         filter_option('severity', $val, %common_exclude);
 154     }
 155     if ($opt eq "sev-inc") {
 156         filter_option('severity', $val, %common_include);
 157     }
 158     if ($opt eq "version") { $common_version = $val; }
 159     if ($opt eq "dist") { $common_dist = $val; }
 160     if ($opt eq "arch") { $common_arch = $val; }
 161 }
 162
 163 sub readparse {
 164     my ($in, $key, $val, %ret);
 165     if (defined $ENV{"QUERY_STRING"} && $ENV{"QUERY_STRING"} ne "") {
 166         $in=$ENV{QUERY_STRING};
 167     } elsif(defined $ENV{"REQUEST_METHOD"}
 168         && $ENV{"REQUEST_METHOD"} eq "POST")
 169     {
 170         read(STDIN,$in,$ENV{CONTENT_LENGTH});
 171     } else {
 172         return;
 173     }
 174     foreach (split(/[&;]/,$in)) {
 175         s/\+/ /g;
 176         ($key, $val) = split(/=/,$_,2);
 177         $key=~s/%(..)/pack("c",hex($1))/ge;
 178         $val=~s/%(..)/pack("c",hex($1))/ge;
 179         if ( exists $ret{$key} ) {
 180             if ( !exists $ret{"&$key"} ) {
 181                 $ret{"&$key"} = [ $ret{$key} ];
 182             }
 183             push @{$ret{"&$key"}},$val;
 184         }
 185         $ret{$key}=$val;
 186     }
 187 $debug = 1 if (defined $ret{"debug"} && $ret{"debug"} eq "aj");
 188     return %ret;
 189 }
 190
 191 sub quitcgi {
 192     my $msg = shift;
 193     print "Content-Type: text/html\n\n";
 194     print "<HTML><HEAD><TITLE>Error</TITLE></HEAD><BODY>\n";
 195     print "An error occurred. Dammit.\n";
 196     print "Error was: $msg.\n";
 197     print "</BODY></HTML>\n";
 198     exit 0;
 199 }
 200
 201 #sub abort {
 202 #    my $msg = shift;
 203 #    my $Archive = $common_archive ? "archive" : "";
 204 #    print header . start_html("Sorry");
 205 #    print "Sorry bug #$msg doesn't seem to be in the $Archive database.\n";
 206 #    print end_html;
 207 #    exit 0;
 208 #}
 209
 210 # Split a package string from the status file into a list of package names.
 211 sub splitpackages {
 212     my $pkgs = shift;
 213     return unless defined $pkgs;
 214     return map lc, split /[ \t?,()]+/, $pkgs;
 215 }
 216
 217 my %_parsedaddrs;
 218 sub getparsedaddrs {
 219     my $addr = shift;
 220     return () unless defined $addr;
 221     return @{$_parsedaddrs{$addr}} if exists $_parsedaddrs{$addr};
 222     @{$_parsedaddrs{$addr}} = Mail::Address->parse($addr);
 223     return @{$_parsedaddrs{$addr}};
 224 }
 225
 226 # Generate a comma-separated list of HTML links to each package given in
 227 # $pkgs. $pkgs may be empty, in which case an empty string is returned, or
 228 # it may be a comma-separated list of package names.
 229 sub htmlpackagelinks {
 230     my $pkgs = shift;
 231     return unless defined $pkgs and $pkgs ne '';
 232     my $strong = shift;
 233     my @pkglist = splitpackages($pkgs);
 234
 235     my $openstrong  = $strong ? '<strong>' : '';
 236     my $closestrong = $strong ? '</strong>' : '';
 237
 238     return 'Package' . (@pkglist > 1 ? 's' : '') . ': ' .
 239            join(', ',
 240                 map {
 241                     '<a href="' . pkgurl($_) . '">' .
 242                     $openstrong . htmlsanit($_) . $closestrong . '</a>'
 243                 } @pkglist
 244            ) . ";\n";
 245 }
 246
 247 # Generate a comma-separated list of HTML links to each address given in
 248 # $addresses, which should be a comma-separated list of RFC822 addresses.
 249 # $urlfunc should be a reference to a function like mainturl or submitterurl
 250 # which returns the URL for each individual address.
 251 sub htmladdresslinks {
 252     my ($prefixfunc, $urlfunc, $addresses) = @_;
 253     if (defined $addresses and $addresses ne '') {
 254         my @addrs = getparsedaddrs($addresses);
 255         my $prefix = (ref $prefixfunc) ? $prefixfunc->(scalar @addrs)
 256                                        : $prefixfunc;
 257         return $prefix .
 258                join ', ', map { sprintf '<a href="%s">%s</a>',
 259                                         $urlfunc->($_->address),
 260                                         htmlsanit($_->format) || '(unknown)'
 261                               } @addrs;
 262     } else {
 263         my $prefix = (ref $prefixfunc) ? $prefixfunc->(1) : $prefixfunc;
 264         return sprintf '%s<a href="%s">(unknown)</a>', $prefix, $urlfunc->('');
 265     }
 266 }
 267
 268 # Generate a comma-separated list of HTML links to each maintainer given in
 269 # $maints, which should be a comma-separated list of RFC822 addresses.
 270 sub htmlmaintlinks {
 271     my ($prefixfunc, $maints) = @_;
 272     return htmladdresslinks($prefixfunc, \&mainturl, $maints);
 273 }
 274
 275 sub htmlindexentry {
 276     my $ref = shift;
 277     my %status = %{getbugstatus($ref)};
 278     return htmlindexentrystatus(%status) if (%status);
 279     return "";
 280 }
 281
 282 sub htmlindexentrystatus {
 283     my $s = shift;
 284     my %status = %{$s};
 285
 286     my $result = "";
 287
 288     if  ($status{severity} eq 'normal') {
 289         $showseverity = '';
 290     } elsif (isstrongseverity($status{severity})) {
 291         $showseverity = "<strong>Severity: $status{severity}</strong>;\n";
 292     } else {
 293         $showseverity = "Severity: <em>$status{severity}</em>;\n";
 294     }
 295
 296     $result .= htmlpackagelinks($status{"package"}, 1);
 297     $result .= $showseverity;
 298     $result .= htmladdresslinks("Reported by: ", \&submitterurl,
 299                                 $status{originator});
 300     $result .= ";\nOwned by: " . htmlsanit($status{owner})
 301                if length $status{owner};
 302     $result .= ";\nTags: <strong>"
 303                  . htmlsanit(join(", ", sort(split(/\s+/, $status{tags}))))
 304                  . "</strong>"
 305                        if (length($status{tags}));
 306
 307     my @merged= split(/ /,$status{mergedwith});
 308     my $mseparator= ";\nmerged with ";
 309     for my $m (@merged) {
 310         $result .= $mseparator."<A href=\"" . bugurl($m) . "\">#$m</A>";
 311         $mseparator= ", ";
 312     }
 313
 314     if (@{$status{found_versions}}) {
 315         $result .= ";\nfound in ";
 316         $result .= (@{$status{found_versions}} == 1) ? 'version '
 317                                                      : 'versions ';
 318         $result .= join ', ', map htmlsanit($_), @{$status{found_versions}};
 319     }
 320
 321     if (@{$status{fixed_versions}}) {
 322         $result .= ";\n<strong>fixed</strong> in ";
 323         $result .= (@{$status{fixed_versions}} == 1) ? 'version '
 324                                                      : 'versions ';
 325         $result .= join ', ', map htmlsanit($_), @{$status{fixed_versions}};
 326         if (length($status{done})) {
 327             $result .= ' by ' . htmlsanit($status{done});
 328         }
 329     } elsif (length($status{done})) {
 330         $result .= ";\n<strong>Done:</strong> " . htmlsanit($status{done});
 331         $days = ceil($debbugs::gRemoveAge - -M buglog($status{id}));
 332         if ($days >= 0) {
 333             $result .= ";\n<strong>Will be archived:</strong>" . ( $days == 0 ? " today" : $days == 1 ? " in $days day" : " in $days days" );
 334         } else {
 335             $result .= ";\n<strong>Archived</strong>";
 336         }
 337     }
 338
 339     unless (length($status{done})) {
 340         if (length($status{forwarded})) {
 341             $result .= ";\n<strong>Forwarded</strong> to "
 342                        . maybelink($status{forwarded});
 343         }
 344         my $daysold = int((time - $status{date}) / 86400);   # seconds to days
 345         if ($daysold >= 7) {
 346             my $font = "";
 347             my $efont = "";
 348             $font = "em" if ($daysold > 30);
 349             $font = "strong" if ($daysold > 60);
 350             $efont = "</$font>" if ($font);
 351             $font = "<$font>" if ($font);
 352
 353             my $yearsold = int($daysold / 365);
 354             $daysold -= $yearsold * 365;
 355
 356             $result .= ";\n $font";
 357             my @age;
 358             push @age, "1 year" if ($yearsold == 1);
 359             push @age, "$yearsold years" if ($yearsold > 1);
 360             push @age, "1 day" if ($daysold == 1);
 361             push @age, "$daysold days" if ($daysold > 1);
 362             $result .= join(" and ", @age);
 363             $result .= " old$efont";
 364         }
 365     }
 366
 367     $result .= ".";
 368
 369     return $result;
 370 }
 371
 372 sub urlargs {
 373     my $args = '';
 374     $args .= "&archive=yes" if $common_archive;
 375     $args .= "&repeatmerged=no" unless $common_repeatmerged;
 376     $args .= "&version=$common_version" if defined $common_version;
 377     $args .= "&dist=$common_dist" if defined $common_dist;
 378     $args .= "&arch=$common_arch" if defined $common_arch;
 379     return $args;
 380 }
 381
 382 sub submitterurl {
 383     my $ref = shift || "";
 384     my $params = "submitter=" . emailfromrfc822($ref);
 385     $params .= urlargs();
 386     return urlsanit("pkgreport.cgi" . "?" . $params);
 387 }
 388
 389 sub mainturl {
 390     my $ref = shift || "";
 391     my $params = "maint=" . emailfromrfc822($ref);
 392     $params .= urlargs();
 393     return urlsanit("pkgreport.cgi" . "?" . $params);
 394 }
 395
 396 sub pkgurl {
 397     my $ref = shift;
 398     my $params = "pkg=$ref";
 399     $params .= urlargs();
 400     return urlsanit("pkgreport.cgi" . "?" . "$params");
 401 }
 402
 403 sub srcurl {
 404     my $ref = shift;
 405     my $params = "src=$ref";
 406     $params .= urlargs();
 407     return urlsanit("pkgreport.cgi" . "?" . "$params");
 408 }
 409
 410 sub tagurl {
 411     my $ref = shift;
 412     my $params = "tag=$ref";
 413     $params .= urlargs();
 414     return urlsanit("pkgreport.cgi" . "?" . "$params");
 415 }
 416
 417 sub urlsanit {
 418     my $url = shift;
 419     $url =~ s/%/%25/g;
 420     $url =~ s/#/%23/g;
 421     $url =~ s/\+/%2b/g;
 422     my %saniarray = ('<','lt', '>','gt', '&','amp', '"','quot');
 423     $url =~ s/([<>&"])/\&$saniarray{$1};/g;
 424     return $url;
 425 }
 426
 427 sub htmlsanit {
 428     my %saniarray = ('<','lt', '>','gt', '&','amp', '"','quot');
 429     my $in = shift || "";
 430     $in =~ s/([<>&"])/\&$saniarray{$1};/g;
 431     return $in;
 432 }
 433
 434 sub maybelink {
 435     my $in = shift;
 436     if ($in =~ /^[a-zA-Z0-9+.-]+:/) { # RFC 1738 scheme
 437         return qq{<a href="$in">} . htmlsanit($in) . '</a>';
 438     } else {
 439         return htmlsanit($in);
 440     }
 441 }
 442
 443 sub bugurl {
 444     my $ref = shift;
 445     my $params = "bug=$ref";
 446     foreach my $val (@_) {
 447         $params .= "\&msg=$1" if ($val =~ /^msg=([0-9]+)/);
 448         $params .= "\&archive=yes" if (!$common_archive && $val =~ /^archive.*$/);
 449     }
 450     $params .= "&archive=yes" if ($common_archive);
 451     $params .= "&repeatmerged=no" unless ($common_repeatmerged);
 452
 453     return urlsanit("bugreport.cgi" . "?" . "$params");
 454 }
 455
 456 sub dlurl {
 457     my $ref = shift;
 458     my $params = "bug=$ref";
 459     my $filename = '';
 460     foreach my $val (@_) {
 461         $params .= "\&$1=$2" if ($val =~ /^(msg|att)=([0-9]+)/);
 462         $filename = $1 if ($val =~ /^filename=(.*)$/);
 463     }
 464     $params .= "&archive=yes" if ($common_archive);
 465     my $pathinfo = '';
 466     $pathinfo = "/$filename" if $filename ne '';
 467
 468     return urlsanit("bugreport.cgi$pathinfo?$params");
 469 }
 470
 471 sub mboxurl {
 472     my $ref = shift;
 473     return urlsanit("bugreport.cgi" . "?" . "bug=$ref&mbox=yes");
 474 }
 475
 476 sub allbugs {
 477     return @{getbugs(sub { 1 })};
 478 }
 479
 480 sub bugmatches(\%\%) {
 481     my ($hash, $status) = @_;
 482     foreach my $key( keys( %$hash ) ) {
 483         my $value = $hash->{$key};
 484         my $sub = $field_match{$key};
 485         return 1 if ($sub->($key, $value, $status));
 486     }
 487     return 0;
 488 }
 489 sub bugfilter($%) {
 490     my ($bug, %status) = @_;
 491     our (%seenmerged);
 492     if (%common_include) {
 493         return 1 if (!bugmatches(%common_include, %status));
 494     }
 495     if (%common_exclude) {
 496         return 1 if (bugmatches(%common_exclude, %status));
 497     }
 498     my @merged = sort {$a<=>$b} $bug, split(/ /, $status{mergedwith});
 499     return 1 unless ($common_repeatmerged || !$seenmerged{$merged[0]});
 500     $seenmerged{$merged[0]} = 1;
 501     return 0;
 502 }
 503
 504 sub htmlizebugs {
 505     $b = $_[0];
 506     my @bugs = @$b;
 507     my $anydone = 0;
 508
 509     my @status = ();
 510     my %count;
 511     my $header = '';
 512     my $footer = '';
 513
 514     if (@bugs == 0) {
 515         return "<HR><H2>No reports found!</H2></HR>\n";
 516     }
 517
 518     if ( $common_bug_reverse ) {
 519         @bugs = sort {$b<=>$a} @bugs;
 520     } else {
 521         @bugs = sort {$a<=>$b} @bugs;
 522     }
 523     my %seenmerged;
 524     foreach my $bug (@bugs) {
 525         my %status = %{getbugstatus($bug)};
 526         next unless %status;
 527         next if bugfilter($bug, %status);
 528
 529         my $html = sprintf "<li><a href=\"%s\">#%d: %s</a>\n<br>",
 530             bugurl($bug), $bug, htmlsanit($status{subject});
 531         $html .= htmlindexentrystatus(\%status) . "\n";
 532         my $key = join( '_', map( {$status{$_}} @common_grouping ) );
 533         $section{$key} .= $html;
 534         $count{"_$key"}++;
 535         foreach my $grouping ( @common_grouping ) {
 536             $count{"${grouping}_$status{$grouping}"}++;
 537         }
 538         $anydone = 1 if $status{pending} eq 'done';
 539         push @status, [ $bug, \%status, $html ];
 540     }
 541
 542     my $result = "";
 543     if ($common_raw_sort) {
 544         $result .= "<UL>\n" . join("", map( { $_->[ 2 ] } @status ) ) . "</UL>\n";
 545     } else {
 546         my (@order, @headers);
 547         for( my $i = 0; $i < @common_grouping; $i++ ) {
 548             my $grouping_name = $common_grouping[ $i ];
 549             my @items = @{ $common_grouping_order{ $grouping_name } };
 550             @items = reverse( @items ) if ( $common_reverse{ $grouping_name } );
 551             my @neworder = ();
 552             my @newheaders = ();
 553             if ( @order ) {
 554                 foreach my $grouping ( @items ) {
 555                     push @neworder, map( { "${_}_$grouping" } @order );
 556                     push @newheaders, map( { "$_ - $common_headers{$grouping_name}{$grouping}" } @headers );
 557                 }
 558                 @order = @neworder;
 559                 @headers = @newheaders;
 560             } else {
 561                 push @order, @items;
 562                 push @headers, map( { $common_headers{$common_grouping[$i]}{$_} } @items );
 563             }
 564         }
 565         $header .= "<ul>\n";
 566         for ( my $i = 0; $i < @order; $i++ ) {
 567             my $order = $order[ $i ];
 568             next unless defined $section{$order};
 569             my $count = $count{"_$order"};
 570             my $bugs = $count == 1 ? "bug" : "bugs";
 571             $header .= "<li><a href=\"#$order\">$headers[$i]</a> ($count $bugs)</li>\n";
 572         }
 573         $header .= "</ul>\n";
 574         for ( my $i = 0; $i < @order; $i++ ) {
 575             my $order = $order[ $i ];
 576             next unless defined $section{$order};
 577             if ($common{show_list_header}) {
 578                 my $count = $count{"_$order"};
 579                 my $bugs = $count == 1 ? "bug" : "bugs";
 580                 $result .= "<HR><H2><a name=\"$order\"></a>$headers[$i] ($count $bugs)</H2>\n";
 581             } else {
 582                 $result .= "<HR><H2>$headers[$i]</H2>\n";
 583             }
 584             $result .= "<UL>\n";
 585             $result .= $section{$order};
 586             $result .= "</UL>\n";
 587         }
 588         $footer .= "<ul>\n";
 589         foreach my $grouping ( @common_grouping ) {
 590             my $local_result = '';
 591             foreach my $key ( @{$common_grouping_order{ $grouping }} ) {
 592                 my $count = $count{"${grouping}_$key"};
 593                 next if !$count;
 594                 $local_result .= "<li>$count $common_headers{$grouping}{$key}</li>\n";
 595             }
 596             if ( $local_result ) {
 597                 $footer .= "<li>$common_grouping_display{$grouping}<ul>\n$local_result</ul></li>\n";
 598             }
 599         }
 600         $footer .= "</ul>\n";
 601     }
 602
 603     $result = $header . $result if ( $common{show_list_header} );
 604     $result .= $debbugs::gHTMLExpireNote if $gRemoveAge and $anydone;
 605     $result .= "<hr>" . $footer if ( $common{show_list_footer} );
 606     return $result;
 607 }
 608
 609 sub countbugs {
 610     my $bugfunc = shift;
 611     if ($common_archive) {
 612         open I, "<$debbugs::gSpoolDir/index.archive"
 613             or &quitcgi("$debbugs::gSpoolDir/index.archive: $!");
 614     } else {
 615         open I, "<$debbugs::gSpoolDir/index.db"
 616             or &quitcgi("$debbugs::gSpoolDir/index.db: $!");
 617     }
 618
 619     my %count = ();
 620     while(<I>)
 621     {
 622         if (m/^(\S+)\s+(\d+)\s+(\d+)\s+(\S+)\s+\[\s*([^]]*)\s*\]\s+(\w+)\s+(.*)$/) {
 623             my @x = $bugfunc->(pkg => $1, bug => $2, status => $4,
 624                                submitter => $5, severity => $6, tags => $7);
 625             local $_;
 626             $count{$_}++ foreach @x;
 627         }
 628     }
 629     close I;
 630     return %count;
 631 }
 632
 633 sub getbugs {
 634     my $bugfunc = shift;
 635     my $opt = shift;
 636
 637     my @result = ();
 638
 639     if (!$common_archive && defined $opt &&
 640         -e "$debbugs::gSpoolDir/by-$opt.idx")
 641     {
 642         my %lookup;
 643 print STDERR "optimized\n" if ($debug);
 644         tie %lookup, DB_File => "$debbugs::gSpoolDir/by-$opt.idx", O_RDONLY
 645             or die "$0: can't open $debbugs::gSpoolDir/by-$opt.idx ($!)\n";
 646         while ($key = shift) {
 647             my $bugs = $lookup{$key};
 648             if (defined $bugs) {
 649                 push @result, (unpack 'N*', $bugs);
 650             }
 651         }
 652         untie %lookup;
 653 print STDERR "done optimized\n" if ($debug);
 654     } else {
 655         if ( $common_archive ) {
 656             open I, "<$debbugs::gSpoolDir/index.archive"
 657                 or &quitcgi("$debbugs::gSpoolDir/index.archive: $!");
 658         } else {
 659             open I, "<$debbugs::gSpoolDir/index.db"
 660                 or &quitcgi("$debbugs::gSpoolDir/index.db: $!");
 661         }
 662         while(<I>) {
 663             if (m/^(\S+)\s+(\d+)\s+(\d+)\s+(\S+)\s+\[\s*([^]]*)\s*\]\s+(\w+)\s+(.*)$/) {
 664                 if ($bugfunc->(pkg => $1, bug => $2, status => $4,
 665                             submitter => $5, severity => $6, tags => $7))
 666                 {
 667                     push (@result, $2);
 668                 }
 669             }
 670         }
 671         close I;
 672     }
 673     @result = sort {$a <=> $b} @result;
 674     return \@result;
 675 }
 676
 677 sub emailfromrfc822 {
 678     my $email = shift;
 679     $email =~ s/\s*\(.*\)\s*//;
 680     $email = $1 if ($email =~ m/<(.*)>/);
 681     return $email;
 682 }
 683
 684 sub maintencoded {
 685     my $input = shift;
 686     my $encoded = '';
 687
 688     while ($input =~ m/\W/) {
 689         $encoded.=$`.sprintf("-%02x_",unpack("C",$&));
 690         $input= $';
 691     }
 692
 693     $encoded.= $input;
 694     $encoded =~ s/-2e_/\./g;
 695     $encoded =~ s/^([^,]+)-20_-3c_(.*)-40_(.*)-3e_/$1,$2,$3,/;
 696     $encoded =~ s/^(.*)-40_(.*)-20_-28_([^,]+)-29_$/,$1,$2,$3/;
 697     $encoded =~ s/-20_/_/g;
 698     $encoded =~ s/-([^_]+)_-/-$1/g;
 699     return $encoded;
 700 }
 701
 702 my $_maintainer;
 703 sub getmaintainers {
 704     return $_maintainer if $_maintainer;
 705     my %maintainer;
 706
 707     open(MM,"$gMaintainerFile") or &quitcgi("open $gMaintainerFile: $!");
 708     while(<MM>) {
 709         next unless m/^(\S+)\s+(\S.*\S)\s*$/;
 710         ($a,$b)=($1,$2);
 711         $a =~ y/A-Z/a-z/;
 712         $maintainer{$a}= $b;
 713     }
 714     close(MM);
 715     if (defined $gMaintainerFileOverride) {
 716         open(MM,"$gMaintainerFileOverride") or &quitcgi("open $gMaintainerFileOverride: $!");
 717         while(<MM>) {
 718             next unless m/^(\S+)\s+(\S.*\S)\s*$/;
 719             ($a,$b)=($1,$2);
 720             $a =~ y/A-Z/a-z/;
 721             $maintainer{$a}= $b;
 722         }
 723         close(MM);
 724     }
 725     $_maintainer = \%maintainer;
 726     return $_maintainer;
 727 }
 728
 729 my $_pkgsrc;
 730 my $_pkgcomponent;
 731 sub getpkgsrc {
 732     return $_pkgsrc if $_pkgsrc;
 733     return {} unless defined $gPackageSource;
 734     my %pkgsrc;
 735     my %pkgcomponent;
 736
 737     open(MM,"$gPackageSource") or &quitcgi("open $gPackageSource: $!");
 738     while(<MM>) {
 739         next unless m/^(\S+)\s+(\S+)\s+(\S.*\S)\s*$/;
 740         ($a,$b,$c)=($1,$2,$3);
 741         $a =~ y/A-Z/a-z/;
 742         $pkgsrc{$a}= $c;
 743         $pkgcomponent{$a}= $b;
 744     }
 745     close(MM);
 746     $_pkgsrc = \%pkgsrc;
 747     $_pkgcomponent = \%pkgcomponent;
 748     return $_pkgsrc;
 749 }
 750
 751 sub getpkgcomponent {
 752     return $_pkgcomponent if $_pkgcomponent;
 753     getpkgsrc();
 754     return $_pkgcomponent;
 755 }
 756
 757 my $_pseudodesc;
 758 sub getpseudodesc {
 759     return $_pseudodesc if $_pseudodesc;
 760     my %pseudodesc;
 761
 762     open(PSEUDO, "< $gPseudoDescFile") or &quitcgi("open $gPseudoDescFile: $!");
 763     while(<PSEUDO>) {
 764         next unless m/^(\S+)\s+(\S.*\S)\s*$/;
 765         $pseudodesc{lc $1} = $2;
 766     }
 767     close(PSEUDO);
 768     $_pseudodesc = \%pseudodesc;
 769     return $_pseudodesc;
 770 }
 771
 772 sub getbugstatus {
 773     my $bugnum = shift;
 774
 775     my %status;
 776
 777     my $location = getbuglocation( $bugnum, 'summary' );
 778     return {} if ( !$location );
 779     %status = %{ readbug( $bugnum, $location ) };
 780     $status{ id } = $bugnum;
 781
 782     $status{found_versions} = [];
 783     $status{fixed_versions} = [];
 784     if (defined $gVersionBugsDir and
 785             (defined $common_version or defined $common_dist)) {
 786         my $bughash = get_hashname($bugnum);
 787         if (open BUGVER, "< $gVersionBugsDir/$bughash/$bugnum.versions") {
 788             local $_;
 789             while (<BUGVER>) {
 790                 if (/^Found-in: (.*)/i) {
 791                     $status{found_versions} = [split ' ', $1];
 792                 } elsif (/^Fixed-in: (.*)/i) {
 793                     $status{fixed_versions} = [split ' ', $1];
 794                 }
 795             }
 796             close BUGVER;
 797         }
 798     }
 799
 800     $status{tags} = $status{keywords};
 801     my %tags = map { $_ => 1 } split ' ', $status{tags};
 802
 803     $status{"package"} =~ s/\s*$//;
 804     $status{"package"} = 'unknown' if ($status{"package"} eq '');
 805     $status{"severity"} = 'normal' if ($status{"severity"} eq '');
 806
 807     $status{"pending"} = 'pending';
 808     $status{"pending"} = 'forwarded'        if (length($status{"forwarded"}));
 809     $status{"pending"} = 'pending-fixed'    if ($tags{pending});
 810     $status{"pending"} = 'fixed'            if ($tags{fixed});
 811
 812     my $version;
 813     if (defined $common_version) {
 814         $version = $common_version;
 815     } elsif (defined $common_dist) {
 816         $version = getversion($status{package}, $common_dist, $common_arch);
 817     }
 818
 819     if (defined $version) {
 820         my $buggy = buggyversion($bugnum, $version, \%status);
 821         if ($buggy eq 'absent') {
 822             $status{"pending"} = 'absent';
 823         } elsif ($buggy eq 'fixed') {
 824             $status{"pending"} = 'done';
 825         }
 826     }
 827
 828     if (length($status{done}) and
 829             (not defined $version or not @{$status{fixed_versions}})) {
 830         $status{"pending"} = 'done';
 831     }
 832
 833     return \%status;
 834 }
 835
 836 sub getsrcpkgs {
 837     my $src = shift;
 838     return () if !$src;
 839     my %pkgsrc = %{getpkgsrc()};
 840     my @pkgs;
 841     foreach ( keys %pkgsrc ) {
 842         push @pkgs, $_ if $pkgsrc{$_} eq $src;
 843     }
 844     return @pkgs;
 845 }
 846
 847 sub buglog {
 848     my $bugnum = shift;
 849     my $location = getbuglocation($bugnum, 'log');
 850     return getbugcomponent($bugnum, 'log', $location) if ($location);
 851     $location = getbuglocation($bugnum, 'log.gz');
 852     return getbugcomponent($bugnum, 'log.gz', $location);
 853 }
 854
 855 my %_versionobj;
 856 sub buggyversion {
 857     my ($bug, $ver, $status) = @_;
 858     return '' unless defined $gVersionPackagesDir;
 859     my $src = getpkgsrc()->{$status->{package}};
 860     $src = $status->{package} unless defined $src;
 861
 862     my $tree;
 863     if (exists $_versionobj{$src}) {
 864         $tree = $_versionobj{$src};
 865     } else {
 866         $tree = Debbugs::Versions->new(\&DpkgVer::vercmp);
 867         if (open VERFILE, "< $gVersionPackagesDir/$src") {
 868             $tree->load(\*VERFILE);
 869             close VERFILE;
 870         }
 871         $_versionobj{$src} = $tree;
 872     }
 873
 874     return $tree->buggy($ver, $status->{found_versions},
 875                         $status->{fixed_versions});
 876 }
 877
 878 my %_versions;
 879 sub getversion {
 880     my ($pkg, $dist, $arch) = @_;
 881     return undef unless defined $gVersionIndex;
 882     $dist = 'unstable' unless defined $dist;
 883     $arch = 'i386' unless defined $arch;
 884
 885     unless (tied %_versions) {
 886         tie %_versions, 'MLDBM', $gVersionIndex, O_RDONLY
 887             or die "can't open versions index: $!";
 888     }
 889
 890     return $_versions{$pkg}{$dist}{$arch};
 891 }
 892
 893 1;