cgi/common.pl

   1 #!/usr/bin/perl -w
   2
   3 use DB_File;
   4 use Fcntl qw/O_RDONLY/;
   5 use Mail::Address;
   6 use MLDBM qw/DB_File/;
   7 use POSIX qw/ceil/;
   8
   9 $config_path = '/etc/debbugs';
  10 $lib_path = '/usr/lib/debbugs';
  11 require "$lib_path/errorlib";
  12
  13 use Debbugs::Versions;
  14 use Debbugs::MIME qw(decode_rfc1522);
  15
  16 $MLDBM::RemoveTaint = 1;
  17
  18 my $common_archive = 0;
  19 my $common_repeatmerged = 1;
  20 my %common_include = ();
  21 my %common_exclude = ();
  22 my $common_raw_sort = 0;
  23 my $common_bug_reverse = 0;
  24
  25 my %common_reverse = (
  26     'pending' => 0,
  27     'severity' => 0,
  28 );
  29 my %common = (
  30     'show_list_header' => 1,
  31     'show_list_footer' => 1,
  32 );
  33
  34 sub exact_field_match {
  35     my ($field, $values, $status) = @_;
  36     my @values = @$values;
  37     my @ret = grep {$_ eq $status->{$field} } @values;
  38     $#ret != -1;
  39 }
  40 sub contains_field_match {
  41     my ($field, $values, $status) = @_;
  42     foreach my $data (@$values) {
  43         return 1 if (index($status->{$field}, $data) > -1);
  44     }
  45     return 0;
  46 }
  47
  48 sub detect_user_agent {
  49     my $userAgent = $ENV{HTTP_USER_AGENT};
  50     return { 'name' => 'unknown' } unless defined $userAgent;
  51     return { 'name' => 'links' } if ( $userAgent =~ m,^ELinks,);
  52     return { 'name' => 'lynx' } if ( $userAgent =~ m,^Lynx,);
  53     return { 'name' => 'wget' } if ( $userAgent =~ m,^Wget,);
  54     return { 'name' => 'gecko' } if ( $userAgent =~ m,^Mozilla.* Gecko/,);
  55     return { 'name' => 'ie' } if ( $userAgent =~ m,^.*MSIE.*,);
  56     return { 'name' => 'unknown' };
  57 }
  58
  59 my %field_match = (
  60     'subject' => \&contains_field_match,
  61     'tags' => sub {
  62         my ($field, $values, $status) = @_;
  63         my %values = map {$_=>1} @$values;
  64         foreach my $t (split /\s+/, $status->{$field}) {
  65             return 1 if (defined $values{$t});
  66         }
  67         return 0;
  68     },
  69     'severity' => \&exact_field_match,
  70     'pending' => \&exact_field_match,
  71     'originator' => \%contains_field_match,
  72     'forwarded' => \%contains_field_match,
  73     'owner' => \%contains_field_match,
  74 );
  75 my @common_grouping = ( 'severity', 'pending' );
  76 my %common_grouping_order = (
  77     'pending' => [ qw( pending forwarded pending-fixed fixed done absent ) ],
  78     'severity' => \@debbugs::gSeverityList,
  79 );
  80 my %common_grouping_display = (
  81     'pending' => 'Status',
  82     'severity' => 'Severity',
  83 );
  84 my %common_headers = (
  85     'pending' => {
  86         "pending"       => "outstanding",
  87         "pending-fixed" => "pending upload",
  88         "fixed"         => "fixed in NMU",
  89         "done"          => "resolved",
  90         "forwarded"     => "forwarded to upstream software authors",
  91         "absent"        => "not applicable to this version",
  92     },
  93     'severity' => \%debbugs::gSeverityDisplay,
  94 );
  95
  96 my $common_version;
  97 my $common_dist;
  98 my $common_arch;
  99
 100 my $debug = 0;
 101
 102 sub array_option($) {
 103     my ($val) = @_;
 104     my @vals;
 105     @vals = ( $val ) if (ref($val) eq "" && $val );
 106     @vals = ( $$val ) if (ref($val) eq "SCALAR" && $$val );
 107     @vals = @{$val} if (ref($val) eq "ARRAY" );
 108     return @vals;
 109 }
 110
 111 sub filter_include_exclude($\%) {
 112     my ($val, $filter_map) = @_;
 113     my @vals = array_option($val);
 114     my @data = map {
 115         if (/^([^:]*):(.*)$/) { if ($1 eq 'subj') { ['subject', $2]; } else { [$1, $2] } } else { ['tags', $_] }
 116     } split /[\s,]+/, join ',', @vals;
 117     foreach my $data (@data) {
 118         &quitcgi("Invalid filter key: '$data->[0]'") if (!exists($field_match{$data->[0]}));
 119         push @{$filter_map->{$data->[0]}}, $data->[1];
 120     }
 121 }
 122
 123 sub filter_option($$\%) {
 124     my ($key, $val, $filter_map) = @_;
 125     my @vals = array_option($val);
 126     foreach $val (@vals) {
 127         push @{$filter_map->{$key}}, $val;
 128     }
 129 }
 130
 131 sub set_option {
 132     my ($opt, $val) = @_;
 133     if ($opt =~ m/^show_list_(foot|head)er$/) { $common{$opt} = $val; }
 134     if ($opt eq "archive") { $common_archive = $val; }
 135     if ($opt eq "repeatmerged") { $common_repeatmerged = $val; }
 136     if ($opt eq "exclude") {
 137         filter_include_exclude($val, %common_exclude);
 138     }
 139     if ($opt eq "include") {
 140         filter_include_exclude($val, %common_include);
 141     }
 142     if ($opt eq "raw") { $common_raw_sort = $val; }
 143     if ($opt eq "bug-rev") { $common_bug_reverse = $val; }
 144     if ($opt eq "pend-rev") { $common_reverse{pending} = $val; }
 145     if ($opt eq "sev-rev") { $common_reverse{severity} = $val; }
 146     if ($opt eq "pend-exc") {
 147         filter_option('pending', $val, %common_exclude);
 148     }
 149     if ($opt eq "pend-inc") {
 150         filter_option('pending', $val, %common_include);
 151     }
 152     if ($opt eq "sev-exc") {
 153         filter_option('severity', $val, %common_exclude);
 154     }
 155     if ($opt eq "sev-inc") {
 156         filter_option('severity', $val, %common_include);
 157     }
 158     if ($opt eq "version") { $common_version = $val; }
 159     if ($opt eq "dist") { $common_dist = $val; }
 160     if ($opt eq "arch") { $common_arch = $val; }
 161 }
 162
 163 sub readparse {
 164     my ($in, $key, $val, %ret);
 165     if (defined $ENV{"QUERY_STRING"} && $ENV{"QUERY_STRING"} ne "") {
 166         $in=$ENV{QUERY_STRING};
 167     } elsif(defined $ENV{"REQUEST_METHOD"}
 168         && $ENV{"REQUEST_METHOD"} eq "POST")
 169     {
 170         read(STDIN,$in,$ENV{CONTENT_LENGTH});
 171     } else {
 172         return;
 173     }
 174     foreach (split(/[&;]/,$in)) {
 175         s/\+/ /g;
 176         ($key, $val) = split(/=/,$_,2);
 177         $key=~s/%(..)/pack("c",hex($1))/ge;
 178         $val=~s/%(..)/pack("c",hex($1))/ge;
 179         if ( exists $ret{$key} ) {
 180             if ( !exists $ret{"&$key"} ) {
 181                 $ret{"&$key"} = [ $ret{$key} ];
 182             }
 183             push @{$ret{"&$key"}},$val;
 184         }
 185         $ret{$key}=$val;
 186     }
 187 $debug = 1 if (defined $ret{"debug"} && $ret{"debug"} eq "aj");
 188     return %ret;
 189 }
 190
 191 sub quitcgi {
 192     my $msg = shift;
 193     print "Content-Type: text/html\n\n";
 194     print "<HTML><HEAD><TITLE>Error</TITLE></HEAD><BODY>\n";
 195     print "An error occurred. Dammit.\n";
 196     print "Error was: $msg.\n";
 197     print "</BODY></HTML>\n";
 198     exit 0;
 199 }
 200
 201 #sub abort {
 202 #    my $msg = shift;
 203 #    my $Archive = $common_archive ? "archive" : "";
 204 #    print header . start_html("Sorry");
 205 #    print "Sorry bug #$msg doesn't seem to be in the $Archive database.\n";
 206 #    print end_html;
 207 #    exit 0;
 208 #}
 209
 210 # Split a package string from the status file into a list of package names.
 211 sub splitpackages {
 212     my $pkgs = shift;
 213     return unless defined $pkgs;
 214     return map lc, split /[ \t?,()]+/, $pkgs;
 215 }
 216
 217 my %_parsedaddrs;
 218 sub getparsedaddrs {
 219     my $addr = shift;
 220     return () unless defined $addr;
 221     return @{$_parsedaddrs{$addr}} if exists $_parsedaddrs{$addr};
 222     @{$_parsedaddrs{$addr}} = Mail::Address->parse($addr);
 223     return @{$_parsedaddrs{$addr}};
 224 }
 225
 226 # Generate a comma-separated list of HTML links to each package given in
 227 # $pkgs. $pkgs may be empty, in which case an empty string is returned, or
 228 # it may be a comma-separated list of package names.
 229 sub htmlpackagelinks {
 230     my $pkgs = shift;
 231     return unless defined $pkgs and $pkgs ne '';
 232     my $strong = shift;
 233     my @pkglist = splitpackages($pkgs);
 234
 235     my $openstrong  = $strong ? '<strong>' : '';
 236     my $closestrong = $strong ? '</strong>' : '';
 237
 238     return 'Package' . (@pkglist > 1 ? 's' : '') . ': ' .
 239            join(', ',
 240                 map {
 241                     '<a href="' . pkgurl($_) . '">' .
 242                     $openstrong . htmlsanit($_) . $closestrong . '</a>'
 243                 } @pkglist
 244            ) . ";\n";
 245 }
 246
 247 # Generate a comma-separated list of HTML links to each maintainer given in
 248 # $maints, which should be a comma-separated list of RFC822 addresses.
 249 sub htmlmaintlinks {
 250     my ($prefixfunc, $maints) = @_;
 251     if (defined $maints and $maints ne '') {
 252         my @maintaddrs = getparsedaddrs($maints);
 253         my $prefix = (ref $prefixfunc) ? $prefixfunc->(scalar @maintaddrs)
 254                                        : $prefixfunc;
 255         return $prefix .
 256                join ', ', map { sprintf '<a href="%s">%s</a>',
 257                                         mainturl($_->address),
 258                                         htmlsanit($_->format) || '(unknown)'
 259                               } @maintaddrs;
 260     } else {
 261         my $prefix = (ref $prefixfunc) ? $prefixfunc->(1) : $prefixfunc;
 262         return sprintf '%s<a href="%s">(unknown)</a>', $prefix, mainturl('');
 263     }
 264 }
 265
 266 sub htmlindexentry {
 267     my $ref = shift;
 268     my %status = %{getbugstatus($ref)};
 269     return htmlindexentrystatus(%status) if (%status);
 270     return "";
 271 }
 272
 273 sub htmlindexentrystatus {
 274     my $s = shift;
 275     my %status = %{$s};
 276
 277     my $result = "";
 278
 279     if  ($status{severity} eq 'normal') {
 280         $showseverity = '';
 281     } elsif (isstrongseverity($status{severity})) {
 282         $showseverity = "<strong>Severity: $status{severity}</strong>;\n";
 283     } else {
 284         $showseverity = "Severity: <em>$status{severity}</em>;\n";
 285     }
 286
 287     $result .= htmlpackagelinks($status{"package"}, 1);
 288     $result .= $showseverity;
 289     $result .= "Reported by: <a href=\"" . submitterurl($status{originator})
 290                . "\">" . htmlsanit($status{originator}) . "</a>";
 291     $result .= ";\nOwned by: " . htmlsanit($status{owner})
 292                if length $status{owner};
 293     $result .= ";\nTags: <strong>"
 294                  . htmlsanit(join(", ", sort(split(/\s+/, $status{tags}))))
 295                  . "</strong>"
 296                        if (length($status{tags}));
 297
 298     my @merged= split(/ /,$status{mergedwith});
 299     my $mseparator= ";\nmerged with ";
 300     for my $m (@merged) {
 301         $result .= $mseparator."<A href=\"" . bugurl($m) . "\">#$m</A>";
 302         $mseparator= ", ";
 303     }
 304
 305     if (@{$status{found_versions}}) {
 306         $result .= ";\nfound in ";
 307         $result .= (@{$status{found_versions}} == 1) ? 'version '
 308                                                      : 'versions ';
 309         $result .= join ', ', map htmlsanit($_), @{$status{found_versions}};
 310     }
 311
 312     if (@{$status{fixed_versions}}) {
 313         $result .= ";\n<strong>fixed</strong> in ";
 314         $result .= (@{$status{fixed_versions}} == 1) ? 'version '
 315                                                      : 'versions ';
 316         $result .= join ', ', map htmlsanit($_), @{$status{fixed_versions}};
 317         if (length($status{done})) {
 318             $result .= ' by ' . htmlsanit($status{done});
 319         }
 320     } elsif (length($status{done})) {
 321         $result .= ";\n<strong>Done:</strong> " . htmlsanit($status{done});
 322         $days = ceil($debbugs::gRemoveAge - -M buglog($status{id}));
 323         if ($days >= 0) {
 324             $result .= ";\n<strong>Will be archived:</strong>" . ( $days == 0 ? " today" : $days == 1 ? " in $days day" : " in $days days" );
 325         } else {
 326             $result .= ";\n<strong>Archived</strong>";
 327         }
 328     }
 329
 330     unless (length($status{done})) {
 331         if (length($status{forwarded})) {
 332             $result .= ";\n<strong>Forwarded</strong> to "
 333                        . maybelink($status{forwarded});
 334         }
 335         my $daysold = int((time - $status{date}) / 86400);   # seconds to days
 336         if ($daysold >= 7) {
 337             my $font = "";
 338             my $efont = "";
 339             $font = "em" if ($daysold > 30);
 340             $font = "strong" if ($daysold > 60);
 341             $efont = "</$font>" if ($font);
 342             $font = "<$font>" if ($font);
 343
 344             my $yearsold = int($daysold / 365);
 345             $daysold -= $yearsold * 365;
 346
 347             $result .= ";\n $font";
 348             my @age;
 349             push @age, "1 year" if ($yearsold == 1);
 350             push @age, "$yearsold years" if ($yearsold > 1);
 351             push @age, "1 day" if ($daysold == 1);
 352             push @age, "$daysold days" if ($daysold > 1);
 353             $result .= join(" and ", @age);
 354             $result .= " old$efont";
 355         }
 356     }
 357
 358     $result .= ".";
 359
 360     return $result;
 361 }
 362
 363 sub urlargs {
 364     my $args = '';
 365     $args .= "&archive=yes" if $common_archive;
 366     $args .= "&repeatmerged=no" unless $common_repeatmerged;
 367     $args .= "&version=$common_version" if defined $common_version;
 368     $args .= "&dist=$common_dist" if defined $common_dist;
 369     $args .= "&arch=$common_arch" if defined $common_arch;
 370     return $args;
 371 }
 372
 373 sub submitterurl {
 374     my $ref = shift || "";
 375     my $params = "submitter=" . emailfromrfc822($ref);
 376     $params .= urlargs();
 377     return urlsanit("pkgreport.cgi" . "?" . $params);
 378 }
 379
 380 sub mainturl {
 381     my $ref = shift || "";
 382     my $params = "maint=" . emailfromrfc822($ref);
 383     $params .= urlargs();
 384     return urlsanit("pkgreport.cgi" . "?" . $params);
 385 }
 386
 387 sub pkgurl {
 388     my $ref = shift;
 389     my $params = "pkg=$ref";
 390     $params .= urlargs();
 391     return urlsanit("pkgreport.cgi" . "?" . "$params");
 392 }
 393
 394 sub srcurl {
 395     my $ref = shift;
 396     my $params = "src=$ref";
 397     $params .= urlargs();
 398     return urlsanit("pkgreport.cgi" . "?" . "$params");
 399 }
 400
 401 sub tagurl {
 402     my $ref = shift;
 403     my $params = "tag=$ref";
 404     $params .= urlargs();
 405     return urlsanit("pkgreport.cgi" . "?" . "$params");
 406 }
 407
 408 sub urlsanit {
 409     my $url = shift;
 410     $url =~ s/%/%25/g;
 411     $url =~ s/#/%23/g;
 412     $url =~ s/\+/%2b/g;
 413     my %saniarray = ('<','lt', '>','gt', '&','amp', '"','quot');
 414     $url =~ s/([<>&"])/\&$saniarray{$1};/g;
 415     return $url;
 416 }
 417
 418 sub htmlsanit {
 419     my %saniarray = ('<','lt', '>','gt', '&','amp', '"','quot');
 420     my $in = shift || "";
 421     $in =~ s/([<>&"])/\&$saniarray{$1};/g;
 422     return $in;
 423 }
 424
 425 sub maybelink {
 426     my $in = shift;
 427     if ($in =~ /^[a-zA-Z0-9+.-]+:/) { # RFC 1738 scheme
 428         return qq{<a href="$in">} . htmlsanit($in) . '</a>';
 429     } else {
 430         return htmlsanit($in);
 431     }
 432 }
 433
 434 sub bugurl {
 435     my $ref = shift;
 436     my $params = "bug=$ref";
 437     foreach my $val (@_) {
 438         $params .= "\&msg=$1" if ($val =~ /^msg=([0-9]+)/);
 439         $params .= "\&archive=yes" if (!$common_archive && $val =~ /^archive.*$/);
 440     }
 441     $params .= "&archive=yes" if ($common_archive);
 442     $params .= "&repeatmerged=no" unless ($common_repeatmerged);
 443
 444     return urlsanit("bugreport.cgi" . "?" . "$params");
 445 }
 446
 447 sub dlurl {
 448     my $ref = shift;
 449     my $params = "bug=$ref";
 450     my $filename = '';
 451     foreach my $val (@_) {
 452         $params .= "\&$1=$2" if ($val =~ /^(msg|att)=([0-9]+)/);
 453         $filename = $1 if ($val =~ /^filename=(.*)$/);
 454     }
 455     $params .= "&archive=yes" if ($common_archive);
 456     my $pathinfo = '';
 457     $pathinfo = "/$filename" if $filename ne '';
 458
 459     return urlsanit("bugreport.cgi$pathinfo?$params");
 460 }
 461
 462 sub mboxurl {
 463     my $ref = shift;
 464     return urlsanit("bugreport.cgi" . "?" . "bug=$ref&mbox=yes");
 465 }
 466
 467 sub allbugs {
 468     return @{getbugs(sub { 1 })};
 469 }
 470
 471 sub bugmatches(\%\%) {
 472     my ($hash, $status) = @_;
 473     foreach my $key( keys( %$hash ) ) {
 474         my $value = $hash->{$key};
 475         my $sub = $field_match{$key};
 476         return 1 if ($sub->($key, $value, $status));
 477     }
 478     return 0;
 479 }
 480 sub bugfilter($%) {
 481     my ($bug, %status) = @_;
 482     our (%seenmerged);
 483     if (%common_include) {
 484         return 1 if (!bugmatches(%common_include, %status));
 485     }
 486     if (%common_exclude) {
 487         return 1 if (bugmatches(%common_exclude, %status));
 488     }
 489     my @merged = sort {$a<=>$b} $bug, split(/ /, $status{mergedwith});
 490     return 1 unless ($common_repeatmerged || !$seenmerged{$merged[0]});
 491     $seenmerged{$merged[0]} = 1;
 492     return 0;
 493 }
 494
 495 sub htmlizebugs {
 496     $b = $_[0];
 497     my @bugs = @$b;
 498     my $anydone = 0;
 499
 500     my @status = ();
 501     my %count;
 502     my $header = '';
 503     my $footer = '';
 504
 505     if (@bugs == 0) {
 506         return "<HR><H2>No reports found!</H2></HR>\n";
 507     }
 508
 509     if ( $common_bug_reverse ) {
 510         @bugs = sort {$b<=>$a} @bugs;
 511     } else {
 512         @bugs = sort {$a<=>$b} @bugs;
 513     }
 514     my %seenmerged;
 515     foreach my $bug (@bugs) {
 516         my %status = %{getbugstatus($bug)};
 517         next unless %status;
 518         next if bugfilter($bug, %status);
 519
 520         my $html = sprintf "<li><a href=\"%s\">#%d: %s</a>\n<br>",
 521             bugurl($bug), $bug, htmlsanit($status{subject});
 522         $html .= htmlindexentrystatus(\%status) . "\n";
 523         my $key = join( '_', map( {$status{$_}} @common_grouping ) );
 524         $section{$key} .= $html;
 525         $count{"_$key"}++;
 526         foreach my $grouping ( @common_grouping ) {
 527             $count{"${grouping}_$status{$grouping}"}++;
 528         }
 529         $anydone = 1 if $status{pending} eq 'done';
 530         push @status, [ $bug, \%status, $html ];
 531     }
 532
 533     my $result = "";
 534     if ($common_raw_sort) {
 535         $result .= "<UL>\n" . join("", map( { $_->[ 2 ] } @status ) ) . "</UL>\n";
 536     } else {
 537         my (@order, @headers);
 538         for( my $i = 0; $i < @common_grouping; $i++ ) {
 539             my $grouping_name = $common_grouping[ $i ];
 540             my @items = @{ $common_grouping_order{ $grouping_name } };
 541             @items = reverse( @items ) if ( $common_reverse{ $grouping_name } );
 542             my @neworder = ();
 543             my @newheaders = ();
 544             if ( @order ) {
 545                 foreach my $grouping ( @items ) {
 546                     push @neworder, map( { "${_}_$grouping" } @order );
 547                     push @newheaders, map( { "$_ - $common_headers{$grouping_name}{$grouping}" } @headers );
 548                 }
 549                 @order = @neworder;
 550                 @headers = @newheaders;
 551             } else {
 552                 push @order, @items;
 553                 push @headers, map( { $common_headers{$common_grouping[$i]}{$_} } @items );
 554             }
 555         }
 556         $header .= "<ul>\n";
 557         for ( my $i = 0; $i < @order; $i++ ) {
 558             my $order = $order[ $i ];
 559             next unless defined $section{$order};
 560             my $count = $count{"_$order"};
 561             my $bugs = $count == 1 ? "bug" : "bugs";
 562             $header .= "<li><a href=\"#$order\">$headers[$i]</a> ($count $bugs)</li>\n";
 563         }
 564         $header .= "</ul>\n";
 565         for ( my $i = 0; $i < @order; $i++ ) {
 566             my $order = $order[ $i ];
 567             next unless defined $section{$order};
 568             if ($common{show_list_header}) {
 569                 my $count = $count{"_$order"};
 570                 my $bugs = $count == 1 ? "bug" : "bugs";
 571                 $result .= "<HR><H2><a name=\"$order\"></a>$headers[$i] ($count $bugs)</H2>\n";
 572             } else {
 573                 $result .= "<HR><H2>$headers[$i]</H2>\n";
 574             }
 575             $result .= "<UL>\n";
 576             $result .= $section{$order};
 577             $result .= "</UL>\n";
 578         }
 579         $footer .= "<ul>\n";
 580         foreach my $grouping ( @common_grouping ) {
 581             my $local_result = '';
 582             foreach my $key ( @{$common_grouping_order{ $grouping }} ) {
 583                 my $count = $count{"${grouping}_$key"};
 584                 next if !$count;
 585                 $local_result .= "<li>$count $common_headers{$grouping}{$key}</li>\n";
 586             }
 587             if ( $local_result ) {
 588                 $footer .= "<li>$common_grouping_display{$grouping}<ul>\n$local_result</ul></li>\n";
 589             }
 590         }
 591         $footer .= "</ul>\n";
 592     }
 593
 594     $result = $header . $result if ( $common{show_list_header} );
 595     $result .= $debbugs::gHTMLExpireNote if $gRemoveAge and $anydone;
 596     $result .= "<hr>" . $footer if ( $common{show_list_footer} );
 597     return $result;
 598 }
 599
 600 sub countbugs {
 601     my $bugfunc = shift;
 602     if ($common_archive) {
 603         open I, "<$debbugs::gSpoolDir/index.archive"
 604             or &quitcgi("$debbugs::gSpoolDir/index.archive: $!");
 605     } else {
 606         open I, "<$debbugs::gSpoolDir/index.db"
 607             or &quitcgi("$debbugs::gSpoolDir/index.db: $!");
 608     }
 609
 610     my %count = ();
 611     while(<I>)
 612     {
 613         if (m/^(\S+)\s+(\d+)\s+(\d+)\s+(\S+)\s+\[\s*([^]]*)\s*\]\s+(\w+)\s+(.*)$/) {
 614             my @x = $bugfunc->(pkg => $1, bug => $2, status => $4,
 615                                submitter => $5, severity => $6, tags => $7);
 616             local $_;
 617             $count{$_}++ foreach @x;
 618         }
 619     }
 620     close I;
 621     return %count;
 622 }
 623
 624 sub getbugs {
 625     my $bugfunc = shift;
 626     my $opt = shift;
 627
 628     my @result = ();
 629
 630     if (!$common_archive && defined $opt &&
 631         -e "$debbugs::gSpoolDir/by-$opt.idx")
 632     {
 633         my %lookup;
 634 print STDERR "optimized\n" if ($debug);
 635         tie %lookup, DB_File => "$debbugs::gSpoolDir/by-$opt.idx", O_RDONLY
 636             or die "$0: can't open $debbugs::gSpoolDir/by-$opt.idx ($!)\n";
 637         while ($key = shift) {
 638             my $bugs = $lookup{$key};
 639             if (defined $bugs) {
 640                 push @result, (unpack 'N*', $bugs);
 641             }
 642         }
 643         untie %lookup;
 644 print STDERR "done optimized\n" if ($debug);
 645     } else {
 646         if ( $common_archive ) {
 647             open I, "<$debbugs::gSpoolDir/index.archive"
 648                 or &quitcgi("$debbugs::gSpoolDir/index.archive: $!");
 649         } else {
 650             open I, "<$debbugs::gSpoolDir/index.db"
 651                 or &quitcgi("$debbugs::gSpoolDir/index.db: $!");
 652         }
 653         while(<I>) {
 654             if (m/^(\S+)\s+(\d+)\s+(\d+)\s+(\S+)\s+\[\s*([^]]*)\s*\]\s+(\w+)\s+(.*)$/) {
 655                 if ($bugfunc->(pkg => $1, bug => $2, status => $4,
 656                             submitter => $5, severity => $6, tags => $7))
 657                 {
 658                     push (@result, $2);
 659                 }
 660             }
 661         }
 662         close I;
 663     }
 664     @result = sort {$a <=> $b} @result;
 665     return \@result;
 666 }
 667
 668 sub emailfromrfc822 {
 669     my $email = shift;
 670     $email =~ s/\s*\(.*\)\s*//;
 671     $email = $1 if ($email =~ m/<(.*)>/);
 672     return $email;
 673 }
 674
 675 sub maintencoded {
 676     my $input = shift;
 677     my $encoded = '';
 678
 679     while ($input =~ m/\W/) {
 680         $encoded.=$`.sprintf("-%02x_",unpack("C",$&));
 681         $input= $';
 682     }
 683
 684     $encoded.= $input;
 685     $encoded =~ s/-2e_/\./g;
 686     $encoded =~ s/^([^,]+)-20_-3c_(.*)-40_(.*)-3e_/$1,$2,$3,/;
 687     $encoded =~ s/^(.*)-40_(.*)-20_-28_([^,]+)-29_$/,$1,$2,$3/;
 688     $encoded =~ s/-20_/_/g;
 689     $encoded =~ s/-([^_]+)_-/-$1/g;
 690     return $encoded;
 691 }
 692
 693 my $_maintainer;
 694 sub getmaintainers {
 695     return $_maintainer if $_maintainer;
 696     my %maintainer;
 697
 698     open(MM,"$gMaintainerFile") or &quitcgi("open $gMaintainerFile: $!");
 699     while(<MM>) {
 700         next unless m/^(\S+)\s+(\S.*\S)\s*$/;
 701         ($a,$b)=($1,$2);
 702         $a =~ y/A-Z/a-z/;
 703         $maintainer{$a}= $b;
 704     }
 705     close(MM);
 706     if (defined $gMaintainerFileOverride) {
 707         open(MM,"$gMaintainerFileOverride") or &quitcgi("open $gMaintainerFileOverride: $!");
 708         while(<MM>) {
 709             next unless m/^(\S+)\s+(\S.*\S)\s*$/;
 710             ($a,$b)=($1,$2);
 711             $a =~ y/A-Z/a-z/;
 712             $maintainer{$a}= $b;
 713         }
 714         close(MM);
 715     }
 716     $_maintainer = \%maintainer;
 717     return $_maintainer;
 718 }
 719
 720 my $_pkgsrc;
 721 my $_pkgcomponent;
 722 sub getpkgsrc {
 723     return $_pkgsrc if $_pkgsrc;
 724     return {} unless defined $gPackageSource;
 725     my %pkgsrc;
 726     my %pkgcomponent;
 727
 728     open(MM,"$gPackageSource") or &quitcgi("open $gPackageSource: $!");
 729     while(<MM>) {
 730         next unless m/^(\S+)\s+(\S+)\s+(\S.*\S)\s*$/;
 731         ($a,$b,$c)=($1,$2,$3);
 732         $a =~ y/A-Z/a-z/;
 733         $pkgsrc{$a}= $c;
 734         $pkgcomponent{$a}= $b;
 735     }
 736     close(MM);
 737     $_pkgsrc = \%pkgsrc;
 738     $_pkgcomponent = \%pkgcomponent;
 739     return $_pkgsrc;
 740 }
 741
 742 sub getpkgcomponent {
 743     return $_pkgcomponent if $_pkgcomponent;
 744     getpkgsrc();
 745     return $_pkgcomponent;
 746 }
 747
 748 my $_pseudodesc;
 749 sub getpseudodesc {
 750     return $_pseudodesc if $_pseudodesc;
 751     my %pseudodesc;
 752
 753     open(PSEUDO, "< $gPseudoDescFile") or &quitcgi("open $gPseudoDescFile: $!");
 754     while(<PSEUDO>) {
 755         next unless m/^(\S+)\s+(\S.*\S)\s*$/;
 756         $pseudodesc{lc $1} = $2;
 757     }
 758     close(PSEUDO);
 759     $_pseudodesc = \%pseudodesc;
 760     return $_pseudodesc;
 761 }
 762
 763 sub getbugstatus {
 764     my $bugnum = shift;
 765
 766     my %status;
 767
 768     my $location = getbuglocation( $bugnum, 'summary' );
 769     return {} if ( !$location );
 770     %status = %{ readbug( $bugnum, $location ) };
 771     $status{ id } = $bugnum;
 772
 773     $status{found_versions} = [];
 774     $status{fixed_versions} = [];
 775     if (defined $gVersionBugsDir and
 776             (defined $common_version or defined $common_dist)) {
 777         my $bughash = get_hashname($bugnum);
 778         if (open BUGVER, "< $gVersionBugsDir/$bughash/$bugnum.versions") {
 779             local $_;
 780             while (<BUGVER>) {
 781                 if (/^Found-in: (.*)/i) {
 782                     $status{found_versions} = [split ' ', $1];
 783                 } elsif (/^Fixed-in: (.*)/i) {
 784                     $status{fixed_versions} = [split ' ', $1];
 785                 }
 786             }
 787             close BUGVER;
 788         }
 789     }
 790
 791     $status{tags} = $status{keywords};
 792     my %tags = map { $_ => 1 } split ' ', $status{tags};
 793
 794     $status{"package"} =~ s/\s*$//;
 795     $status{"package"} = 'unknown' if ($status{"package"} eq '');
 796     $status{"severity"} = 'normal' if ($status{"severity"} eq '');
 797
 798     $status{"pending"} = 'pending';
 799     $status{"pending"} = 'forwarded'        if (length($status{"forwarded"}));
 800     $status{"pending"} = 'pending-fixed'    if ($tags{pending});
 801     $status{"pending"} = 'fixed'            if ($tags{fixed});
 802
 803     my $version;
 804     if (defined $common_version) {
 805         $version = $common_version;
 806     } elsif (defined $common_dist) {
 807         $version = getversion($status{package}, $common_dist, $common_arch);
 808     }
 809
 810     if (defined $version) {
 811         my $buggy = buggyversion($bugnum, $version, \%status);
 812         if ($buggy eq 'absent') {
 813             $status{"pending"} = 'absent';
 814         } elsif ($buggy eq 'fixed') {
 815             $status{"pending"} = 'done';
 816         }
 817     }
 818
 819     if (length($status{done}) and
 820             (not defined $version or not @{$status{fixed_versions}})) {
 821         $status{"pending"} = 'done';
 822     }
 823
 824     return \%status;
 825 }
 826
 827 sub getsrcpkgs {
 828     my $src = shift;
 829     return () if !$src;
 830     my %pkgsrc = %{getpkgsrc()};
 831     my @pkgs;
 832     foreach ( keys %pkgsrc ) {
 833         push @pkgs, $_ if $pkgsrc{$_} eq $src;
 834     }
 835     return @pkgs;
 836 }
 837
 838 sub buglog {
 839     my $bugnum = shift;
 840     my $location = getbuglocation($bugnum, 'log');
 841     return getbugcomponent($bugnum, 'log', $location) if ($location);
 842     $location = getbuglocation($bugnum, 'log.gz');
 843     return getbugcomponent($bugnum, 'log.gz', $location);
 844 }
 845
 846 my %_versionobj;
 847 sub buggyversion {
 848     my ($bug, $ver, $status) = @_;
 849     return '' unless defined $gVersionPackagesDir;
 850     my $src = getpkgsrc()->{$status->{package}};
 851     $src = $status->{package} unless defined $src;
 852
 853     my $tree;
 854     if (exists $_versionobj{$src}) {
 855         $tree = $_versionobj{$src};
 856     } else {
 857         $tree = Debbugs::Versions->new(\&DpkgVer::vercmp);
 858         if (open VERFILE, "< $gVersionPackagesDir/$src") {
 859             $tree->load(\*VERFILE);
 860             close VERFILE;
 861         }
 862         $_versionobj{$src} = $tree;
 863     }
 864
 865     return $tree->buggy($ver, $status->{found_versions},
 866                         $status->{fixed_versions});
 867 }
 868
 869 my %_versions;
 870 sub getversion {
 871     my ($pkg, $dist, $arch) = @_;
 872     return undef unless defined $gVersionIndex;
 873     $dist = 'unstable' unless defined $dist;
 874     $arch = 'i386' unless defined $arch;
 875
 876     unless (tied %_versions) {
 877         tie %_versions, 'MLDBM', $gVersionIndex, O_RDONLY
 878             or die "can't open versions index: $!";
 879     }
 880
 881     return $_versions{$pkg}{$dist}{$arch};
 882 }
 883
 884 1;