cgi/bugreport.cgi

   1 #!/usr/bin/perl
   2
   3 use warnings;
   4 use strict;
   5
   6 # Sanitize environent for taint
   7 BEGIN{
   8     delete @ENV{qw(IFS CDPATH ENV BASH_ENV)};
   9 }
  10
  11
  12 use POSIX qw(strftime);
  13 use MIME::Parser;
  14 use MIME::Decoder;
  15 use IO::Scalar;
  16 use IO::File;
  17
  18 use Debbugs::Config qw(:globals :text :config);
  19
  20 # for read_log_records
  21 use Debbugs::Log qw(:read);
  22 use Debbugs::Log::Spam;
  23 use Debbugs::CGI qw(:url :html :util :cache :usertags);
  24 use Debbugs::CGI::Bugreport qw(:all);
  25 use Debbugs::Common qw(buglog getmaintainers make_list bug_status);
  26 use Debbugs::Packages qw(getpkgsrc);
  27 use Debbugs::Status qw(splitpackages split_status_fields get_bug_status isstrongseverity);
  28
  29 use Scalar::Util qw(looks_like_number);
  30
  31 use Debbugs::Text qw(:templates);
  32 use URI::Escape qw(uri_escape_utf8);
  33 use List::AllUtils qw(max);
  34
  35
  36 use CGI::Simple;
  37 my $q = new CGI::Simple;
  38 # STDOUT should be using the utf8 io layer
  39 binmode(STDOUT,':raw:encoding(UTF-8)');
  40
  41 my %param = cgi_parameters(query => $q,
  42                            single => [qw(bug msg att boring terse),
  43                                       qw(reverse mbox mime trim),
  44                                       qw(mboxstat mboxmaint archive),
  45                                       qw(repeatmerged avatars),
  46                                      ],
  47                            default => {# msg       => '',
  48                                        boring    => 'no',
  49                                        terse     => 'no',
  50                                        reverse   => 'no',
  51                                        mbox      => 'no',
  52                                        mime      => 'no',
  53                                        mboxstat  => 'no',
  54                                        mboxmaint => 'no',
  55                                        archive   => 'no',
  56                                        repeatmerged => 'yes',
  57                                        avatars   => 'yes',
  58                                       },
  59                           );
  60 # This is craptacular.
  61
  62 my $ref = $param{bug} or quitcgi("No bug number", '400 Bad Request');
  63 $ref =~ /(\d+)/ or quitcgi("Invalid bug number", '400 Bad Request');
  64 $ref = $1;
  65 my $short = "#$ref";
  66 my ($msg) = $param{msg} =~ /^(\d+)$/ if exists $param{msg};
  67 my ($att) = $param{att} =~ /^(\d+)$/ if exists $param{att};
  68 my $boring = $param{'boring'} eq 'yes';
  69 my $terse = $param{'terse'} eq 'yes';
  70 my $reverse = $param{'reverse'} eq 'yes';
  71 my $mbox = $param{'mbox'} eq 'yes';
  72 my $mime = $param{'mime'} eq 'yes';
  73 my $avatars = $param{avatars} eq 'yes';
  74
  75 my $trim_headers = ($param{trim} || ((defined $msg and $msg)?'no':'yes')) eq 'yes';
  76
  77 my $mbox_status_message = $param{mboxstat} eq 'yes';
  78 my $mbox_maint = $param{mboxmaint} eq 'yes';
  79 $mbox = 1 if $mbox_status_message or $mbox_maint;
  80
  81 # Not used by this script directly, but fetch these so that pkgurl() and
  82 # friends can propagate them correctly.
  83 my $archive = $param{'archive'} eq 'yes';
  84 my $repeatmerged = $param{'repeatmerged'} eq 'yes';
  85
  86 my %bugusertags;
  87 my %ut;
  88 my %seen_users;
  89
  90 my $buglog = buglog($ref);
  91 my $bug_status = bug_status($ref);
  92 if (not defined $buglog or not defined $bug_status) {
  93     no_such_bug($q,$ref);
  94 }
  95
  96 sub no_such_bug {
  97     my ($q,$ref) = @_;
  98     print $q->header(-status => 404,
  99                      -content_type => "text/html",
 100                      -charset => 'utf-8',
 101                      -cache_control => 'public, max-age=600',
 102                     );
 103     print fill_in_template(template=>'cgi/no_such_bug',
 104                            variables => {modify_time => strftime('%a, %e %b %Y %T UTC', gmtime),
 105                                          bug_num     => $ref,
 106                                         },
 107                           );
 108     exit 0;
 109 }
 110
 111 ## calculate etag for this bugreport.cgi call
 112 my $etag;
 113 ## identify the files that we need to look at; if someone just wants the mbox,
 114 ## they don't need to see anything but the buglog; otherwise, track what is
 115 ## necessary for the usertags and things to calculate status.
 116
 117 my @dependent_files = ($buglog);
 118 my $need_status = 0;
 119 if (not (($mbox and not $mbox_status_message) or
 120          (defined $att and defined $msg))) {
 121     $need_status = 1;
 122     push @dependent_files,
 123         $bug_status,
 124         defined $config{version_index} ? $config{version_index}:(),
 125         defined $config{binary_source_map} ? $config{binary_source_map}:();
 126 }
 127
 128 ## Identify the users required
 129 for my $user (map {split /[\s*,\s*]+/} make_list($param{users}||[])) {
 130     next unless length($user);
 131     push @dependent_files,Debbugs::User::usertag_file_from_email($user);
 132 }
 133 if (defined $param{usertag}) {
 134     for my $usertag (make_list($param{usertag})) {
 135         my ($user, $tag) = split /:/, $usertag, 2;
 136         push @dependent_files,Debbugs::User::usertag_file_from_email($user);
 137     }
 138 }
 139 $etag =
 140     etag_does_not_match(cgi => $q,
 141                         additional_data => [grep {defined $_ ? $_ :()}
 142                                             values %param
 143                                            ],
 144                         files => [@dependent_files,
 145                                  ],
 146                        );
 147 if (not $etag) {
 148     print $q->header(-status => 304,
 149                      -cache_control => 'public, max-age=600',
 150                      -etag => $etag,
 151                      -charset => 'utf-8',
 152                      -content_type => 'text/html',
 153                     );
 154     print "304: Not modified\n";
 155     exit 0;
 156 }
 157
 158 ## if they're just asking for the head, stop here.
 159 if ($q->request_method() eq 'HEAD' and not defined($att) and not $mbox) {
 160     print $q->header(-status => 200,
 161                      -cache_control => 'public, max-age=600',
 162                      -etag => $etag,
 163                      -charset => 'utf-8',
 164                      -content_type => 'text/html',
 165                     );
 166      exit 0;
 167 }
 168
 169 for my $user (map {split /[\s*,\s*]+/} make_list($param{users}||[])) {
 170     next unless length($user);
 171     add_user($user,\%ut,\%bugusertags,\%seen_users);
 172 }
 173
 174 if (defined $param{usertag}) {
 175      for my $usertag (make_list($param{usertag})) {
 176           my %select_ut = ();
 177           my ($u, $t) = split /:/, $usertag, 2;
 178           Debbugs::User::read_usertags(\%select_ut, $u);
 179           unless (defined $t && $t ne "") {
 180                $t = join(",", keys(%select_ut));
 181           }
 182           add_user($u,\%ut,\%bugusertags,\%seen_users);
 183           push @{$param{tag}}, split /,/, $t;
 184      }
 185 }
 186
 187 my %status;
 188 if ($need_status) {
 189     %status = %{split_status_fields(get_bug_status(bug=>$ref,
 190                                                    bugusertags => \%bugusertags,
 191                                                   ))}
 192 }
 193
 194 my @records;
 195 my $spam;
 196 eval{
 197     @records = read_log_records(bug_num => $ref,inner_file => 1);
 198     $spam = Debbugs::Log::Spam->new(bug_num => $ref);
 199 };
 200 if ($@) {
 201      quitcgi("Bad bug log for $gBug $ref. Unable to read records: $@");
 202 }
 203
 204 my $log='';
 205 my $msg_num = 0;
 206 my $skip_next = 0;
 207 if (defined($msg) and ($msg-1) <= $#records) {
 208      @records = ($records[$msg-1]);
 209      $msg_num = $msg - 1;
 210 }
 211 my @log;
 212 if ( $mbox ) {
 213      binmode(STDOUT,":raw");
 214      my $date = strftime "%a %b %d %T %Y", localtime;
 215      if (@records > 1) {
 216          print $q->header(-type => "application/mbox",
 217                           -cache_control => 'public, max-age=600',
 218                           -etag => $etag,
 219                           content_disposition => qq(attachment; filename="bug_${ref}.mbox"),
 220                          );
 221      }
 222      else {
 223           $msg_num++;
 224           print $q->header(-type => "message/rfc822",
 225                            -cache_control => 'public, max-age=86400',
 226                            -etag => $etag,
 227                            content_disposition => qq(attachment; filename="bug_${ref}_message_${msg_num}.mbox"),
 228                           );
 229      }
 230      if ($mbox_status_message and @records > 1) {
 231           my $status_message='';
 232           my @status_fields = (retitle   => 'subject',
 233                                package   => 'package',
 234                                submitter => 'originator',
 235                                severity  => 'severity',
 236                                tag       => 'tags',
 237                                owner     => 'owner',
 238                                blocks    => 'blocks',
 239                                forward   => 'forward',
 240                               );
 241           my ($key,$value);
 242           while (($key,$value) = splice(@status_fields,0,2)) {
 243                if (defined $status{$value} and length $status{$value}) {
 244                     $status_message .= qq($key $ref $status{$value}\n);
 245                }
 246           }
 247           print STDOUT qq(From unknown $date\n),
 248                create_mime_message([From       => "$gBug#$ref <$ref\@$gEmailDomain>",
 249                                     To         => "$gBug#$ref <$ref\@$gEmailDomain>",
 250                                     Subject    => "Status: $status{subject}",
 251                                     "Reply-To" => "$gBug#$ref <$ref\@$gEmailDomain>",
 252                                    ],
 253                                    <<END,);
 254 $status_message
 255 thanks
 256
 257
 258 END
 259      }
 260      my $message_number=0;
 261      my %seen_message_ids;
 262      for my $record (@records) {
 263           next if $record->{type} !~ /^(?:recips|incoming-recv)$/;
 264           my $wanted_type = $mbox_maint?'recips':'incoming-recv';
 265           # we want to include control messages anyway
 266           my $record_wanted_anyway = 0;
 267           my ($msg_id) = record_regex($record,qr/^Message-Id:\s+<(.+)>/im);
 268           next if defined $msg_id and exists $seen_message_ids{$msg_id};
 269           next if defined $msg_id and $msg_id =~/handler\..+\.ack(?:info|done)?\@/;
 270           $record_wanted_anyway = 1 if record_regex($record,qr/^Received: \(at control\)/);
 271           next if not $boring and not $record->{type} eq $wanted_type and not $record_wanted_anyway and @records > 1;
 272           $seen_message_ids{$msg_id} = 1 if defined $msg_id;
 273           # skip spam messages if we're outputting more than one message
 274           next if @records > 1 and $spam->is_spam($msg_id);
 275       my @lines;
 276       if ($record->{inner_file}) {
 277           push @lines, scalar $record->{fh}->getline;
 278           push @lines, scalar $record->{fh}->getline;
 279           chomp $lines[0];
 280           chomp $lines[1];
 281       } else {
 282           @lines = split( "\n", $record->{text}, -1 );
 283       }
 284           if ( $lines[ 1 ] =~ m/^From / ) {
 285           @lines = reverse @lines;
 286           }
 287           if ( !( $lines[ 0 ] =~ m/^From / ) ) {
 288                unshift @lines, "From unknown $date";
 289        }
 290       print $lines[0]."\n";
 291           print map { s/^(>*From )/>$1/; $_."\n" } @lines[ 1 .. $#lines ];
 292       if ($record->{inner_file}) {
 293           my $fh = $record->{fh};
 294           local $/;
 295           while (<$fh>) {
 296               s/^(>*From )/>$1/gm;
 297               print $_;
 298           }
 299       }
 300      }
 301      exit 0;
 302 }
 303
 304 else {
 305      if (defined $att and defined $msg and @records) {
 306          binmode(STDOUT,":raw");
 307          $msg_num++;
 308          ## allow this to be cached for a week
 309          print "Status: 200 OK\n";
 310          print "Cache-Control: public, max-age=604800\n";
 311          print "Etag: $etag\n";
 312           print handle_email_message($records[0],
 313                                      ref => $ref,
 314                                      msg_num => $msg_num,
 315                                      att => $att,
 316                                      msg => $msg,
 317                                      trim_headers => $trim_headers,
 318                                     );
 319           exit 0;
 320      }
 321      my %seen_msg_ids;
 322      for my $record (@records) {
 323           $msg_num++;
 324           if ($skip_next) {
 325                $skip_next = 0;
 326                next;
 327           }
 328           $skip_next = 1 if $record->{type} eq 'html' and not $boring;
 329           push @log, handle_record($record,$ref,$msg_num,
 330                                    \%seen_msg_ids,
 331                                    trim_headers => $trim_headers,
 332                                    avatars => $avatars,
 333                                    terse => $terse,
 334                                    # if we're only looking at one record, allow
 335                                    # spam to be output
 336                                    spam  => (@records > 1)?$spam:undef,
 337                                   );
 338      }
 339 }
 340
 341 @log = reverse @log if $reverse;
 342 $log = join("\n",@log);
 343
 344
 345 # All of the below should be turned into a template
 346
 347 my %maintainer = %{getmaintainers()};
 348 my %pkgsrc = %{getpkgsrc()};
 349
 350 my $indexentry;
 351 my $showseverity;
 352
 353 my $tpack;
 354 my $tmain;
 355
 356 my $dtime = strftime "%a, %e %b %Y %T UTC", gmtime;
 357
 358 unless (%status) {
 359     no_such_bug($q,$ref);
 360 }
 361
 362 #$|=1;
 363
 364
 365 my @packages = make_list($status{package});
 366
 367
 368 my %packages_affects;
 369 for my $p_a (qw(package affects)) {
 370     foreach my $pkg (make_list($status{$p_a})) {
 371         if ($pkg =~ /^src\:/) {
 372             my ($srcpkg) = $pkg =~ /^src:(.*)/;
 373             $packages_affects{$p_a}{$pkg} =
 374                {maintainer => exists($maintainer{$srcpkg}) ? $maintainer{$srcpkg} : '(unknown)',
 375                 source     => $srcpkg,
 376                 package    => $pkg,
 377                 is_source  => 1,
 378                };
 379         }
 380         else {
 381             $packages_affects{$p_a}{$pkg} =
 382                {maintainer => exists($maintainer{$pkg}) ? $maintainer{$pkg} : '(unknown)',
 383                 exists($pkgsrc{$pkg}) ? (source => $pkgsrc{$pkg}) : (),
 384                 package    => $pkg,
 385                };
 386         }
 387     }
 388 }
 389
 390 # fixup various bits of the status
 391 $status{tags_array} = [sort(make_list($status{tags}))];
 392 $status{date_text} = strftime('%a, %e %b %Y %T UTC', gmtime($status{date}));
 393 $status{mergedwith_array} = [make_list($status{mergedwith})];
 394
 395
 396 my $version_graph = '';
 397 if (@{$status{found_versions}} or @{$status{fixed_versions}}) {
 398      $version_graph = q(<a href=").
 399           html_escape(version_url(package => $status{package},
 400                                   found => $status{found_versions},
 401                                   fixed => $status{fixed_versions},
 402                                  )
 403                      ).
 404           q("><img alt="version graph" src=").
 405           html_escape(version_url(package => $status{package},
 406                                   found => $status{found_versions},
 407                                   fixed => $status{fixed_versions},
 408                                   width => 2,
 409                                   height => 2,
 410                                  )
 411                      ).
 412           qq{"></a>};
 413 }
 414
 415
 416
 417 my @blockedby= make_list($status{blockedby});
 418 $status{blockedby_array} = [];
 419 if (@blockedby && $status{"pending"} ne 'fixed' && ! length($status{done})) {
 420     for my $b (@blockedby) {
 421         my %s = %{get_bug_status($b)};
 422         next if (defined $s{pending} and
 423                  $s{"pending"} eq 'fixed') or
 424                      length $s{done};
 425         push @{$status{blockedby_array}},{bug_num => $b, subject => $s{subject}, status => \%s};
 426    }
 427 }
 428
 429 my @blocks= make_list($status{blocks});
 430 $status{blocks_array} = [];
 431 if (@blocks && $status{"pending"} ne 'fixed' && ! length($status{done})) {
 432     for my $b (@blocks) {
 433         my %s = %{get_bug_status($b)};
 434         next if $s{"pending"} eq 'fixed' || length $s{done};
 435         push @{$status{blocks_array}}, {bug_num => $b, subject => $s{subject}, status => \%s};
 436     }
 437 }
 438
 439 if ($buglog !~ m#^\Q$gSpoolDir/db#) {
 440      $status{archived} = 1;
 441 }
 442
 443 my $descriptivehead = $indexentry;
 444
 445 print $q->header(-type => "text/html",
 446                  -charset => 'utf-8',
 447                  -cache_control => 'public, max-age=300',
 448                  -etag => $etag,
 449                 );
 450
 451 print fill_in_template(template => 'cgi/bugreport',
 452                        variables => {status => \%status,
 453                                      package => $packages_affects{'package'},
 454                                      affects => $packages_affects{'affects'},
 455                                      log           => $log,
 456                                      bug_num       => $ref,
 457                                      version_graph => $version_graph,
 458                                      msg           => $msg,
 459                                      isstrongseverity => \&Debbugs::Status::isstrongseverity,
 460                                      html_escape   => \&Debbugs::CGI::html_escape,
 461                                      uri_escape    => \&URI::Escape::uri_escape_utf8,
 462                                      looks_like_number => \&Scalar::Util::looks_like_number,
 463                                      make_list        => \&Debbugs::Common::make_list,
 464                                     },
 465                        hole_var  => {'&package_links' => \&Debbugs::CGI::package_links,
 466                                      '&bug_links'     => \&Debbugs::CGI::bug_links,
 467                                      '&version_url'   => \&Debbugs::CGI::version_url,
 468                                      '&strftime'      => \&POSIX::strftime,
 469                                      '&maybelink'     => \&Debbugs::CGI::maybelink,
 470                                     },
 471                       );
 472
 473 __END__
 474
 475 # Local Variables:
 476 # indent-tabs-mode: nil
 477 # cperl-indent-level: 4
 478 # End: