Debian/Debhelper/Dh_Getopt.pm

   1 #!/usr/bin/perl -w
   2 #
   3 # Debhelper option processing library.
   4 #
   5 # Joey Hess GPL copyright 1998-2002
   6
   7 package Debian::Debhelper::Dh_Getopt;
   8 use strict;
   9
  10 use Debian::Debhelper::Dh_Lib;
  11 use Getopt::Long;
  12
  13 my %exclude_package;
  14
  15 sub showhelp {
  16         my $prog=basename($0);
  17         print "Usage: $prog [options]\n\n";
  18         print "  $prog is a part of debhelper. See debhelper(7)\n";
  19         print "  and $prog(1) for complete usage instructions.\n";
  20         exit(1);
  21 }
  22
  23 # Passed an option name and an option value, adds packages to the list
  24 # of packages. We need this so the list will be built up in the right
  25 # order.
  26 sub AddPackage { my($option,$value)=@_;
  27         if ($option eq 'i' or $option eq 'indep') {
  28                 push @{$dh{DOPACKAGES}}, getpackages('indep');
  29                 $dh{DOINDEP}=1;
  30         }
  31         elsif ($option eq 'a' or $option eq 'arch') {
  32                 push @{$dh{DOPACKAGES}}, getpackages('arch');
  33                 $dh{DOARCH}=1;
  34         }
  35         elsif ($option eq 'p' or $option eq 'package') {
  36                 push @{$dh{DOPACKAGES}}, $value;
  37         }
  38         elsif ($option eq 's' or $option eq 'same-arch') {
  39                 push @{$dh{DOPACKAGES}}, getpackages('same');
  40                 $dh{DOSAME}=1;
  41         }
  42         else {
  43                 error("bad option $option - should never happen!\n");
  44         }
  45 }
  46
  47 # Adds packages to the list of debug packages.
  48 sub AddDebugPackage { my($option,$value)=@_;
  49         push @{$dh{DEBUGPACKAGES}}, $value;
  50 }
  51
  52 # Add a package to a list of packages that should not be acted on.
  53 sub ExcludePackage { my($option,$value)=@_;
  54         $exclude_package{$value}=1;
  55 }
  56
  57 # Add another item to the exclude list.
  58 sub AddExclude { my($option,$value)=@_;
  59         push @{$dh{EXCLUDE}},$value;
  60 }
  61
  62 # Add a file to the ignore list.
  63 sub AddIgnore { my($option,$file)=@_;
  64         $dh{IGNORE}->{$file}=1;
  65 }
  66
  67 # This collects non-options values.
  68 sub NonOption {
  69         push @{$dh{ARGV}}, @_;
  70 }
  71
  72 sub getoptions {
  73         my $array=shift;
  74         my %options=%{shift()} if ref $_[0];
  75
  76         Getopt::Long::GetOptionsFromArray($array,
  77                 "v" => \$dh{VERBOSE},
  78                 "verbose" => \$dh{VERBOSE},
  79
  80                 "no-act" => \$dh{NO_ACT},
  81
  82                 "i" => \&AddPackage,
  83                 "indep" => \&AddPackage,
  84
  85                 "a" => \&AddPackage,
  86                 "arch" => \&AddPackage,
  87
  88                 "p=s" => \&AddPackage,
  89                 "package=s" => \&AddPackage,
  90
  91                 "N=s" => \&ExcludePackage,
  92                 "no-package=s" => \&ExcludePackage,
  93
  94                 "dbg-package=s" => \&AddDebugPackage,
  95
  96                 "s" => \&AddPackage,
  97                 "same-arch" => \&AddPackage,
  98
  99                 "n" => \$dh{NOSCRIPTS},
 100                 "noscripts" => \$dh{NOSCRIPTS},
 101                 "o" => \$dh{ONLYSCRIPTS},
 102                 "onlyscripts" => \$dh{ONLYSCRIPTS},
 103
 104                 "X=s" => \&AddExclude,
 105                 "exclude=s" => \&AddExclude,
 106
 107                 "d" => \$dh{D_FLAG},
 108
 109                 "k" => \$dh{K_FLAG},
 110                 "keep" => \$dh{K_FLAG},
 111
 112                 "P=s" => \$dh{TMPDIR},
 113                 "tmpdir=s" => \$dh{TMPDIR},
 114
 115                 "u=s", => \$dh{U_PARAMS},
 116
 117                 "V:s", => \$dh{V_FLAG},
 118
 119                 "A" => \$dh{PARAMS_ALL},
 120                 "all" => \$dh{PARAMS_ALL},
 121
 122                 "sourcedir=s" => \$dh{SOURCEDIR},
 123
 124                 "destdir=s" => \$dh{DESTDIR},
 125
 126                 "priority=s" => \$dh{PRIORITY},
 127
 128                 "h|help" => \&showhelp,
 129
 130                 "mainpackage=s" => \$dh{MAINPACKAGE},
 131
 132                 "name=s" => \$dh{NAME},
 133
 134                 "error-handler=s" => \$dh{ERROR_HANDLER},
 135
 136                 "ignore=s" => \&AddIgnore,
 137
 138                 %options,
 139
 140                 "<>" => \&NonOption,
 141         )
 142 }
 143
 144 # Parse options and set %dh values.
 145 sub parseopts {
 146         my $options=shift;
 147
 148         # DH_OPTIONS can contain additional options
 149         # to be parsed like @ARGV, but with unknown options
 150         # skipped.
 151         my @ARGV_extra;
 152         if (defined $ENV{DH_OPTIONS}) {
 153                 $ENV{DH_OPTIONS}=~s/^\s+//;
 154                 $ENV{DH_OPTIONS}=~s/\s+$//;
 155                 @ARGV_extra=split(/\s+/,$ENV{DH_OPTIONS});
 156                 my $ret=getoptions(\@ARGV_extra, $options);
 157                 if (!$ret) {
 158                         warning("warning: ignored unknown options in DH_OPTIONS");
 159                 }
 160         }
 161
 162         my $ret=getoptions(\@ARGV, $options);
 163         if (!$ret) {
 164                 warning("warning: unknown options will be a fatal error in a future debhelper release");
 165                 #error("unknown option; aborting");
 166         }
 167
 168         # Check to see if -V was specified. If so, but no parameters were
 169         # passed, the variable will be defined but empty.
 170         if (defined($dh{V_FLAG})) {
 171                 $dh{V_FLAG_SET}=1;
 172         }
 173
 174         # If we have not been given any packages to act on, assume they
 175         # want us to act on them all. Note we have to do this before excluding
 176         # packages out, below.
 177         if (! defined $dh{DOPACKAGES} || ! @{$dh{DOPACKAGES}}) {
 178                 if ($dh{DOINDEP} || $dh{DOARCH} || $dh{DOSAME}) {
 179                         # User specified that all arch (in)dep package be
 180                         # built, and there are none of that type.
 181                         warning("I have no package to build");
 182                         exit(0);
 183                 }
 184                 push @{$dh{DOPACKAGES}},getpackages();
 185         }
 186
 187         # Remove excluded packages from the list of packages to act on.
 188         # Also unique the list, in case some options were specified that
 189         # added a package to it twice.
 190         my @package_list;
 191         my $package;
 192         my %packages_seen;
 193         foreach $package (@{$dh{DOPACKAGES}}) {
 194                 if (! $exclude_package{$package}) {
 195                         if (! exists $packages_seen{$package}) {
 196                                 $packages_seen{$package}=1;
 197                                 push @package_list, $package;
 198                         }
 199                 }
 200         }
 201         @{$dh{DOPACKAGES}}=@package_list;
 202
 203         # If there are no packages to act on now, it's an error.
 204         if (! defined $dh{DOPACKAGES} || ! @{$dh{DOPACKAGES}}) {
 205                 error("I have no package to build");
 206         }
 207
 208         if (defined $dh{U_PARAMS}) {
 209                 # Split the U_PARAMS up into an array.
 210                 my $u=$dh{U_PARAMS};
 211                 undef $dh{U_PARAMS};
 212                 push @{$dh{U_PARAMS}}, split(/\s+/,$u);
 213         }
 214
 215         # Anything left in @ARGV is options that appeared after a --
 216         # These options are added to the U_PARAMS array, while the
 217         # non-option values we collected replace them in @ARGV;
 218         push @{$dh{U_PARAMS}}, @ARGV, @ARGV_extra;
 219         @ARGV=@{$dh{ARGV}} if exists $dh{ARGV};
 220 }
 221
 222 sub import {
 223         # Enable bundling of short command line options.
 224         Getopt::Long::config("bundling");
 225 }
 226
 227 1