Debian/Debhelper/Buildsystem/makefile.pm

   1 # A buildsystem plugin for handling simple Makefile based projects.
   2 #
   3 # Copyright: © 2008 Joey Hess
   4 #            © 2008-2009 Modestas Vainius
   5 # License: GPL-2+
   6
   7 package Debian::Debhelper::Buildsystem::makefile;
   8
   9 use strict;
  10 use Debian::Debhelper::Dh_Lib;
  11 use base 'Debian::Debhelper::Dh_Buildsystem';
  12
  13 sub get_makecmd_C {
  14         my $self=shift;
  15         if ($self->get_builddir()) {
  16                 return $self->{makecmd} . " -C " . $self->get_builddir();
  17         }
  18         return $self->{makecmd};
  19 }
  20
  21 sub exists_make_target {
  22         my ($self, $target) = @_;
  23         my $makecmd=$self->get_makecmd_C();
  24
  25         # Use make -n to check to see if the target would do
  26         # anything. There's no good way to test if a target exists.
  27         my $ret=`$makecmd -s -n $target 2>/dev/null`;
  28         chomp $ret;
  29         return length($ret);
  30 }
  31
  32 sub make_first_existing_target {
  33         my $self=shift;
  34         my $targets=shift;
  35
  36         foreach my $target (@$targets) {
  37                 if ($self->exists_make_target($target)) {
  38                         $self->doit_in_builddir($self->{makecmd}, $target, @_);
  39                         return $target;
  40                 }
  41         }
  42         return undef;
  43 }
  44
  45 sub DESCRIPTION {
  46         "support for building Makefile based packages (make && make install)"
  47 }
  48
  49 sub new {
  50         my $cls=shift;
  51         my $self=$cls->SUPER::new(@_);
  52         $self->{makecmd} = (exists $ENV{MAKE}) ? $ENV{MAKE} : "make";
  53         return $self;
  54 }
  55
  56 sub check_auto_buildable {
  57         my $self=shift;
  58         my ($action) = @_;
  59
  60         # Handles build, test, install, clean; configure - next class
  61         # XXX JEH shouldn't it also handle configure, just as a no-op?
  62         # XXX MDX No, then cmake.mk would have no chance of hitting for
  63         #         no good reason.
  64         if (grep /^\Q$action\E$/, qw{build test install clean}) {
  65                 # This is always called in the source directory, but generally
  66                 # Makefiles are created (or live) in the the build directory.
  67                 return -e $self->get_buildpath("Makefile") ||
  68                        -e $self->get_buildpath("makefile") ||
  69                        -e $self->get_buildpath("GNUmakefile");
  70         }
  71         return 0;
  72 }
  73
  74 sub build {
  75         my $self=shift;
  76         $self->doit_in_builddir($self->{makecmd}, @_);
  77 }
  78
  79 sub test {
  80         my $self=shift;
  81         $self->make_first_existing_target(['test', 'check'], @_);
  82 }
  83
  84 sub install {
  85         my $self=shift;
  86         my $destdir=shift;
  87         $self->make_first_existing_target(['install'], "DESTDIR=$destdir", @_);
  88 }
  89
  90 sub clean {
  91         my $self=shift;
  92         if (!$self->clean_builddir()) {
  93                 $self->make_first_existing_target(['distclean', 'realclean', 'clean'], @_);
  94         }
  95 }
  96
  97 1;