Debbugs/DB/Load.pm

   1 # This module is part of debbugs, and is released
   2 # under the terms of the GPL version 2, or any later version. See the
   3 # file README and COPYING for more information.
   4 # Copyright 2013 by Don Armstrong <don@donarmstrong.com>.
   5
   6 package Debbugs::DB::Load;
   7
   8 =head1 NAME
   9
  10 Debbugs::DB::Load -- Utility routines for loading the database
  11
  12 =head1 SYNOPSIS
  13
  14
  15 =head1 DESCRIPTION
  16
  17
  18 =head1 BUGS
  19
  20 None known.
  21
  22 =cut
  23
  24 use warnings;
  25 use strict;
  26 use v5.10;
  27 use vars qw($VERSION $DEBUG %EXPORT_TAGS @EXPORT_OK @EXPORT);
  28 use base qw(Exporter);
  29
  30 BEGIN{
  31      ($VERSION) = q$Revision$ =~ /^Revision:\s+([^\s+])/;
  32      $DEBUG = 0 unless defined $DEBUG;
  33
  34      @EXPORT = ();
  35      %EXPORT_TAGS = (load_bug    => [qw(load_bug handle_load_bug_queue load_bug_log)],
  36                      load_debinfo => [qw(load_debinfo)],
  37                      load_package => [qw(load_packages)],
  38                      load_suite => [qw(load_suite)],
  39                     );
  40      @EXPORT_OK = ();
  41      Exporter::export_ok_tags(keys %EXPORT_TAGS);
  42      $EXPORT_TAGS{all} = [@EXPORT_OK];
  43 }
  44
  45 use Params::Validate qw(validate_with :types);
  46 use List::AllUtils qw(natatime);
  47
  48 use Debbugs::Status qw(read_bug split_status_fields);
  49 use Debbugs::DB;
  50 use DateTime;
  51 use Debbugs::Common qw(make_list getparsedaddrs);
  52 use Debbugs::Config qw(:config);
  53 use Debbugs::MIME qw(parse_to_mime_entity decode_rfc1522);
  54 use DateTime::Format::Mail;
  55 use Carp;
  56
  57 =head2 Bug loading
  58
  59 Routines to load bug; exported with :load_bug
  60
  61 =over
  62
  63 =item load_bug
  64
  65      load_bug(db => $schema,
  66               data => split_status_fields($data),
  67               tags => \%tags,
  68               queue => \%queue);
  69
  70 Loads a bug's metadata into the database. (Does not load any messages)
  71
  72 =over
  73
  74 =item db -- Debbugs::DB object
  75
  76 =item data -- Bug data (from read_bug) which has been split with split_status_fields
  77
  78 =item tags -- tag cache (hashref); optional
  79
  80 =item queue -- queue of operations to perform after bug is loaded; optional.
  81
  82 =back
  83
  84 =cut
  85
  86 sub load_bug {
  87     my %param = validate_with(params => \@_,
  88                               spec => {db => {type => OBJECT,
  89                                              },
  90                                        data => {type => HASHREF,
  91                                                 optional => 1,
  92                                                },
  93                                        bug => {type => SCALAR,
  94                                                optional => 1,
  95                                               },
  96                                        tags => {type => HASHREF,
  97                                                 default => sub {return {}},
  98                                                 optional => 1},
  99                                        severities => {type => HASHREF,
 100                                                       default => sub {return {}},
 101                                                       optional => 1,
 102                                                      },
 103                                        queue => {type => HASHREF,
 104                                                  optional => 1},
 105                                        packages => {type => HASHREF,
 106                                                     default => sub {return {}},
 107                                                     optional => 1,
 108                                                    },
 109                                       });
 110     my $s = $param{db};
 111     if (not exists $param{data} and not exists $param{bug}) {
 112         croak "One of data or bug must be provided to load_bug";
 113     }
 114     if (not exists $param{data}) {
 115         $param{data} = read_bug(bug => $param{bug});
 116     }
 117     my $data = $param{data};
 118     my $tags = $param{tags};
 119     my $queue = $param{queue};
 120     my $severities = $param{severities};
 121     my $can_queue = 1;
 122     if (not defined $queue) {
 123         $can_queue = 0;
 124         $queue = {};
 125     }
 126     my %tags;
 127     $data = split_status_fields($data);
 128     for my $tag (make_list($data->{keywords})) {
 129         next unless defined $tag and length $tag;
 130         # this allows for invalid tags. But we'll use this to try to
 131         # find those bugs and clean them up
 132         if (not exists $tags->{$tag}) {
 133             $tags->{$tag} = $s->resultset('Tag')->
 134             find_or_create({tag => $tag});
 135         }
 136         $tags{$tag} = $tags->{$tag};
 137     }
 138     my $severity = length($data->{severity}) ? $data->{severity} :
 139         $config{default_severity};
 140     if (not exists $severities->{$severity}) {
 141         $severities->{$severity} =
 142             $s->resultset('Severity')->
 143             find_or_create({severity => $severity},
 144                           );
 145     }
 146     $severity = $severities->{$severity};
 147     my $bug =
 148         {id => $data->{bug_num},
 149          creation => DateTime->from_epoch(epoch => $data->{date}),
 150          log_modified => DateTime->from_epoch(epoch => $data->{log_modified}),
 151          last_modified => DateTime->from_epoch(epoch => $data->{last_modified}),
 152          archived => $data->{archived},
 153          (defined $data->{unarchived} and length($data->{unarchived}))?
 154          (unarchived => DateTime->from_epoch(epoch => $data->{unarchived})):(),
 155          forwarded => $data->{forwarded} // '',
 156          summary => $data->{summary} // '',
 157          outlook => $data->{outlook} // '',
 158          subject => $data->{subject} // '',
 159          done_full => $data->{done} // '',
 160          severity => $severity,
 161          owner_full => $data->{owner} // '',
 162          submitter_full => $data->{originator} // '',
 163         };
 164     my %addr_map =
 165         (done => 'done',
 166          owner => 'owner',
 167          submitter => 'originator',
 168         );
 169     for my $addr_type (keys %addr_map) {
 170         $bug->{$addr_type} = undef;
 171         next unless defined $data->{$addr_map{$addr_type}} and
 172             length($data->{$addr_map{$addr_type}});
 173         $bug->{$addr_type} =
 174             $s->resultset('Correspondent')->
 175             get_correspondent_id($data->{$addr_map{$addr_type}})
 176     }
 177     my $b = $s->resultset('Bug')->update_or_create($bug) or
 178         die "Unable to update or create bug $bug->{id}";
 179     $s->txn_do(sub {
 180                  $b->set_related_packages('binpackages',
 181                                           [grep {defined $_ and
 182                                                    length $_ and $_ !~ /^src:/}
 183                                            make_list($data->{package})],
 184                                           $param{packages},
 185                                          );
 186                  $b->set_related_packages('srcpackages',
 187                                           [map {s/src://;
 188                                                 $_}
 189                                            grep {defined $_ and
 190                                                    $_ =~ /^src:/}
 191                                            make_list($data->{package})],
 192                                           $param{packages},
 193                                          );
 194                  $b->set_related_packages('affects_binpackages',
 195                                           [grep {defined $_ and
 196                                                    length $_ and $_ !~ /^src:/}
 197                                            make_list($data->{affects})
 198                                           ],
 199                                           $param{packages},
 200                                          );
 201                  $b->set_related_packages('affects_srcpackages',
 202                                           [map {s/src://;
 203                                                 $_}
 204                                            grep {defined $_ and
 205                                                    $_ =~ /^src:/}
 206                                            make_list($data->{affects})],
 207                                           $param{packages},
 208                                          );
 209                  for my $ff (qw(found fixed)) {
 210                        my @elements = $s->resultset('BugVer')->search({bug => $data->{bug_num},
 211                                                                        found  => $ff eq 'found'?1:0,
 212                                                                       });
 213                        my %elements_to_delete = map {($elements[$_]->ver_string(),
 214                                                       $elements[$_])} 0..$#elements;
 215                        my %elements_to_add;
 216                        my @elements_to_keep;
 217                        for my $version (@{$data->{"${ff}_versions"}}) {
 218                            if (exists $elements_to_delete{$version}) {
 219                                push @elements_to_keep,$version;
 220                            } else {
 221                                $elements_to_add{$version} = 1;
 222                            }
 223                        }
 224                        for my $version (@elements_to_keep) {
 225                            delete $elements_to_delete{$version};
 226                        }
 227                        for my $element (keys %elements_to_delete) {
 228                            $elements_to_delete{$element}->delete();
 229                        }
 230                        for my $element (keys %elements_to_add) {
 231                            # find source package and source version id
 232                            my $ne = $s->resultset('BugVer')->new_result({bug => $data->{bug_num},
 233                                                                          ver_string => $element,
 234                                                                          found => $ff eq 'found'?1:0,
 235                                                                         }
 236                                                                        );
 237                            if (my ($src_pkg,$src_ver) = $element =~ m{^([^\/]+)/(.+)$}) {
 238                                my $src_pkg_e = $s->resultset('SrcPkg')->single({pkg => $src_pkg});
 239                                if (defined $src_pkg_e) {
 240                                    $ne->src_pkg($src_pkg_e->id());
 241                                    my $src_ver_e = $s->resultset('SrcVer')->single({src_pkg => $src_pkg_e->id(),
 242                                                                                     ver => $src_ver
 243                                                                                    });
 244                                    $ne->src_ver($src_ver_e->id()) if defined $src_ver_e;
 245                                }
 246                            }
 247                            $ne->insert();
 248                        }
 249                    }
 250                });
 251     ### set bug tags
 252     $s->txn_do(sub {$b->set_tags([values %tags ] )});
 253     # because these bugs reference other bugs which might not exist
 254     # yet, we can't handle them until we've loaded all bugs. queue
 255     # them up.
 256     for my $merge_block (qw(mergedwith blocks)) {
 257         if (@{$data->{$merge_block}||[]}) {
 258             my $count = $s->resultset('Bug')->
 259                 search({id => [@{$data->{$merge_block}}]})->
 260                 count();
 261             # if all of the bugs exist, immediately fix the merge/blocks
 262             if ($count == @{$data->{$merge_block}}) {
 263                 handle_load_bug_queue(db=>$s,
 264                                       queue => {$merge_block,
 265                                                {$data->{bug_num},[@{$data->{$merge_block}}]}
 266                                                });
 267             } else {
 268                 $queue->{$merge_block}{$data->{bug_num}} = [@{$data->{$merge_block}}];
 269             }
 270         }
 271     }
 272
 273     if (not $can_queue and keys %{$queue}) {
 274         handle_load_bug_queue(db => $s,queue => $queue);
 275     }
 276
 277     # still need to handle merges, versions, etc.
 278 }
 279
 280 =item handle_load_bug_queue
 281
 282      handle_load_bug_queue(db => $schema,queue => $queue);
 283
 284 Handles a queue of operations created by load bug. [These operations
 285 are used to handle cases where a bug referenced by a loaded bug may
 286 not exist yet. In cases where the bugs should exist, the queue is
 287 cleared automatically by load_bug if queue is undefined.
 288
 289 =cut
 290
 291 sub handle_load_bug_queue{
 292     my %param = validate_with(params => \@_,
 293                               spec => {db => {type => OBJECT,
 294                                              },
 295                                        queue => {type => HASHREF,
 296                                                 },
 297                                       });
 298     my $s = $param{db};
 299     my $queue = $param{queue};
 300     my %queue_types =
 301         (mergedwith => {set => 'BugMerged',
 302                         columns => [qw(bug merged)],
 303                         bug => 'bug',
 304                        },
 305          blocks => {set => 'BugBlock',
 306                     columns => [qw(bug blocks)],
 307                     bug => 'bug',
 308                    },
 309         );
 310     for my $queue_type (keys %queue_types) {
 311         my $qt = $queue_types{$queue_type};
 312         my @bugs = keys %{$queue->{$queue_type}};
 313         my @entries;
 314         for my $bug (@bugs) {
 315             push @entries,
 316                 map {[$bug,$_]}
 317                 @{$queue->{$queue_type}{$bug}};
 318         }
 319         $s->txn_do(sub {
 320                        $s->resultset($qt->{set})->
 321                            search({$qt->{bug}=>\@bugs})->delete();
 322                        $s->resultset($qt->{set})->
 323                            populate([[@{$qt->{columns}}],
 324                                      @entries]) if @entries;
 325                        }
 326                   );
 327     }
 328 }
 329
 330 =item load_bug_log -- load bug logs
 331
 332        load_bug_log(db  => $s,
 333                     bug => $bug);
 334
 335
 336 =over
 337
 338 =item db -- database
 339
 340 =item bug -- bug whose log should be loaded
 341
 342 =back
 343
 344 =cut
 345
 346 sub load_bug_log {
 347     my %param = validate_with(params => \@_,
 348                               spec => {db => {type => OBJECT,
 349                                              },
 350                                        bug => {type => SCALAR,
 351                                               },
 352                                        queue => {type => HASHREF,
 353                                                  optional => 1},
 354                                       });
 355     my $s = $param{db};
 356     my $msg_num=0;
 357     my %seen_msg_ids;
 358     my $log = Debbugs::Log->new(bug_num => $param{bug}) or
 359         die "Unable to open log for $param{bug} for reading: $!";
 360     while (my $record = $log->read_record()) {
 361         next unless $record->{type} eq 'incoming-recv';
 362         my ($msg_id) = $record->{text} =~ /^Message-Id:\s+<(.+)>/im;
 363         next if defined $msg_id and exists $seen_msg_ids{$msg_id};
 364         $seen_msg_ids{$msg_id} = 1 if defined $msg_id;
 365         next if defined $msg_id and $msg_id =~ /handler\..+\.ack(?:info)?\@/;
 366         my $entity = parse_to_mime_entity($record);
 367         # search for a message with this message id in the database
 368         $msg_id = $entity->head->get('Message-Id') //
 369             $entity->head->get('Resent-Message-ID') //
 370             '';
 371         $msg_id =~ s/^\s*\<//;
 372         $msg_id =~ s/>\s*$//;
 373         # check to see if the subject, to, and from match. if so, it's
 374         # probably the same message.
 375         my $subject = decode_rfc1522($entity->head->get('Subject')//'');
 376         $subject =~ s/\n(?:(\s)\s*|\s*$)//g;
 377         my $to = decode_rfc1522($entity->head->get('To')//'');
 378         $to =~ s/\n(?:(\s)\s*|\s*$)//g;
 379         my $from = decode_rfc1522($entity->head->get('From')//'');
 380         $from =~ s/\n(?:(\s)\s*|\s*$)//g;
 381         my $m = $s->resultset('Message')->
 382             find({msgid => $msg_id,
 383                   from_complete => $from,
 384                   to_complete => $to,
 385                   subject => $subject
 386                  });
 387         if (not defined $m) {
 388             # if not, create a new message
 389             $m = $s->resultset('Message')->
 390                 find_or_create({msgid => $msg_id,
 391                                 from_complete => $from,
 392                                 to_complete => $to,
 393                                 subject => $subject
 394                                });
 395             eval {
 396                 my $date = DateTime::Format::Mail->
 397                     parse_datetime($entity->head->get('Date',0));
 398                 if (abs($date->offset) >= 60 * 60 * 12) {
 399                     $date = $date->set_time_zone('UTC');
 400                 }
 401                 $m->sent_date($date);
 402             };
 403             my $spam = $entity->head->get('X-Spam-Status',0)//'';
 404             if ($spam=~ /score=([\d\.]+)/) {
 405                 $m->spam_score($1);
 406             }
 407             my %corr;
 408             @{$corr{from}} = getparsedaddrs($from);
 409             @{$corr{to}} = getparsedaddrs($to);
 410             @{$corr{cc}} = getparsedaddrs($entity->head->get('Cc'));
 411             # add correspondents if necessary
 412             my @cors;
 413             for my $type (keys %corr) {
 414                 for my $addr (@{$corr{$type}}) {
 415                     my $cor = $s->resultset('Correspondent')->
 416                         get_correspondent_id($addr);
 417                     next unless defined $cor;
 418                     push @cors,
 419                         {correspondent => $cor,
 420                          correspondent_type => $type,
 421                         };
 422                 }
 423             }
 424             $m->update();
 425             $s->txn_do(sub {
 426                            $m->message_correspondents()->delete();
 427                            $m->add_to_message_correspondents(@cors) if
 428                                @cors;
 429                        }
 430                       );
 431         }
 432         my $recv;
 433         if ($entity->head->get('Received',0)
 434             =~ /via spool by (\S+)/) {
 435             $recv = $s->resultset('Correspondent')->
 436                 get_correspondent_id($1);
 437             $m->add_to_message_correspondents({correspondent=>$recv,
 438                                                correspondent_type => 'recv'});
 439         }
 440         # link message to bugs if necessary
 441         $m->find_or_create_related('bug_messages',
 442                                   {bug=>$param{bug},
 443                                    message_number => $msg_num});
 444     }
 445
 446 }
 447
 448 =back
 449
 450 =head2 Debinfo
 451
 452 Commands to handle src and package version loading from debinfo files
 453
 454 =over
 455
 456 =item load_debinfo
 457
 458      load_debinfo($schema,$binname, $binver, $binarch, $srcname, $srcver);
 459
 460
 461
 462 =cut
 463
 464 sub load_debinfo {
 465     my ($s,$binname, $binver, $binarch, $srcname, $srcver,$ct_date,$cache) = @_;
 466     $cache //= {};
 467     my $sp;
 468     if (not defined $cache->{sp}{$srcname}) {
 469         $cache->{sp}{$srcname} =
 470             $s->resultset('SrcPkg')->find_or_create({pkg => $srcname});
 471     }
 472     $sp = $cache->{sp}{$srcname};
 473     # update the creation date if the data we have is earlier
 474     if (defined $ct_date and
 475         (not defined $sp->creation or
 476          $ct_date < $sp->creation)) {
 477         $sp->creation($ct_date);
 478         $sp->last_modified(DateTime->now);
 479         $sp->update;
 480     }
 481     my $sv;
 482     if (not defined $cache->{sv}{$srcname}{$srcver}) {
 483         $cache->{sv}{$srcname}{$srcver} =
 484             $s->resultset('SrcVer')->
 485             find_or_create({src_pkg =>$sp->id(),
 486                             ver => $srcver});
 487     }
 488     $sv = $cache->{sv}{$srcname}{$srcver};
 489     if (defined $ct_date and
 490         (not defined $sv->upload_date() or $ct_date < $sv->upload_date())) {
 491         $sv->upload_date($ct_date);
 492         $sv->update;
 493     }
 494     my $arch;
 495     if (not defined $cache->{arch}{$binarch}) {
 496         $cache->{arch}{$binarch} =
 497             $s->resultset('Arch')->
 498             find_or_create({arch => $binarch},
 499                           )->id();
 500     }
 501     $arch = $cache->{arch}{$binarch};
 502     my $bp;
 503     if (not defined $cache->{bp}{$binname}) {
 504         $cache->{bp}{$binname} =
 505             $s->resultset('BinPkg')->
 506             get_bin_pkg_id($binname);
 507     }
 508     $bp = $cache->{bp}{$binname};
 509     $s->resultset('BinVer')->
 510         get_bin_ver_id($bp,$binver,$arch,$sv->id());
 511 }
 512
 513
 514 =back
 515
 516 =head2 Packages
 517
 518 =over
 519
 520 =item load_package
 521
 522      load_package($schema,$suite,$component,$arch,$pkg)
 523
 524 =cut
 525
 526 sub load_packages {
 527     my ($schema,$suite,$pkgs,$p) = @_;
 528     my $suite_id = $schema->resultset('Suite')->
 529         find_or_create({codename => $suite})->id;
 530     my %maint_cache;
 531     my %arch_cache;
 532     my %source_cache;
 533     my $src_max_last_modified = $schema->resultset('SrcAssociation')->
 534         search_rs({suite => $suite_id},
 535                  {order_by => {-desc => ['me.modified']},
 536                   rows => 1,
 537                   page => 1
 538                  }
 539                  )->single();
 540     my $bin_max_last_modified = $schema->resultset('BinAssociation')->
 541         search_rs({suite => $suite_id},
 542                  {order_by => {-desc => ['me.modified']},
 543                   rows => 1,
 544                   page => 1
 545                  }
 546                  )->single();
 547     my %maints;
 548     my %sources;
 549     my %bins;
 550     for my $pkg_tuple (@{$pkgs}) {
 551         my ($arch,$component,$pkg) = @{$pkg_tuple};
 552         $maints{$pkg->{Maintainer}} = $pkg->{Maintainer};
 553         if ($arch eq 'source') {
 554             my $source = $pkg->{Package};
 555             my $source_ver = $pkg->{Version};
 556             $sources{$source}{$source_ver} = $pkg->{Maintainer};
 557         } else {
 558             my $source = $pkg->{Source} // $pkg->{Package};
 559             my $source_ver = $pkg->{Version};
 560             if ($source =~ /^\s*(\S+) \(([^\)]+)\)\s*$/) {
 561                 ($source,$source_ver) = ($1,$2);
 562             }
 563             $sources{$source}{$source_ver} = $pkg->{Maintainer};
 564             $bins{$arch}{$pkg->{Package}} =
 565                {arch => $arch,
 566                 bin => $pkg->{Package},
 567                 bin_ver => $pkg->{Version},
 568                 src_ver => $source_ver,
 569                 source  => $source,
 570                 maint   => $pkg->{Maintainer},
 571                };
 572         }
 573     }
 574     # Retrieve and Insert new maintainers
 575     my $maints =
 576         $schema->resultset('Maintainer')->
 577         get_maintainers(keys %maints);
 578     my $archs =
 579         $schema->resultset('Arch')->
 580         get_archs(keys %bins);
 581     # We want all of the source package/versions which are in this suite to
 582     # start with
 583     my @sa_to_add;
 584     my @sa_to_del;
 585     my %included_sa;
 586     # Calculate which source packages are no longer in this suite
 587     for my $s ($schema->resultset('SrcPkg')->
 588                src_pkg_and_ver_in_suite($suite)) {
 589         if (not exists $sources{$s->{pkg}} or
 590             not exists $sources{$s->{pkg}}{$s->{src_vers}{ver}}
 591            ) {
 592             push @sa_to_del,
 593                 $s->{src_associations}{id};
 594         }
 595         $included_sa{$s->{pkg}}{$s->{src_vers}} = 1;
 596     }
 597     # Calculate which source packages are newly in this suite
 598     for my $s (keys %sources) {
 599         for my $v (keys %{$sources{$s}}) {
 600             if (not exists $included_sa{$s} and
 601                 not $included_sa{$s}{$v}) {
 602                 push @sa_to_add,
 603                     [$s,$v,$sources{$s}{$v}];
 604             } else {
 605                 $p->update() if defined $p;
 606             }
 607         }
 608     }
 609     # add new source packages
 610     my $it = natatime 100, @sa_to_add;
 611     while (my @v = $it->()) {
 612         $schema->txn_do(
 613             sub {
 614                 for my $svm (@_) {
 615                     my $s_id = $schema->resultset('SrcPkg')->
 616                         get_src_pkg_id($svm->[0]);
 617                     my $sv_id = $schema->resultset('SrcVer')->
 618                         get_src_ver_id($s_id,$svm->[1],$maints->{$svm->[2]});
 619                     $schema->resultset('SrcAssociation')->
 620                         insert_suite_src_ver_association($suite_id,$sv_id);
 621                 }
 622             },
 623                         @v
 624                        );
 625         $p->update($p->last_update()+
 626                    scalar @v) if defined $p;
 627     }
 628     # remove associations for packages not in this suite
 629     if (@sa_to_del) {
 630         $it = natatime 1000, @sa_to_del;
 631         while (my @v = $it->()) {
 632             $schema->
 633                 txn_do(sub {
 634                            $schema->resultset('SrcAssociation')->
 635                                search_rs({id => \@v})->
 636                                delete();
 637                        });
 638         }
 639     }
 640     # update packages in this suite to have a modification time of now
 641     $schema->resultset('SrcAssociation')->
 642         search_rs({suite => $suite_id})->
 643         update({modified => 'NOW()'});
 644     ## Handle binary packages
 645     my @bin_to_del;
 646     my @bin_to_add;
 647     my %included_bin;
 648     # calculate which binary packages are no longer in this suite
 649     for my $b ($schema->resultset('BinPkg')->
 650                bin_pkg_and_ver_in_suite($suite)) {
 651         if (not exists $bins{$b->{arch}{arch}} or
 652             not exists $bins{$b->{arch}{arch}}{$b->{pkg}} or
 653             ($bins{$b->{arch}{arch}}{$b->{pkg}}{bin_ver} ne
 654              $b->{bin_vers}{ver}
 655             )
 656            ) {
 657             push @bin_to_del,
 658                 $b->{bin_associations}{id};
 659         }
 660         $included_bin{$b->{arch}{arch}}{$b->{pkg}} =
 661             $b->{bin_vers}{ver};
 662     }
 663     # calculate which binary packages are newly in this suite
 664     for my $a (keys %bins) {
 665         for my $pkg (keys %{$bins{$a}}) {
 666             if (not exists $included_bin{$a} or
 667                 not exists $included_bin{$a}{$pkg} or
 668                 $bins{$a}{$pkg}{bin_ver} ne
 669                 $included_bin{$a}{$pkg}) {
 670                 push @bin_to_add,
 671                     $bins{$a}{$pkg};
 672             } else {
 673                 $p->update() if defined $p;
 674             }
 675         }
 676     }
 677     $it = natatime 100, @bin_to_add;
 678     while (my @v = $it->()) {
 679         $schema->txn_do(
 680         sub {
 681             for my $bvm (@_) {
 682                 my $s_id = $schema->resultset('SrcPkg')->
 683                     get_src_pkg_id($bvm->{source});
 684                 my $sv_id = $schema->resultset('SrcVer')->
 685                     get_src_ver_id($s_id,$bvm->{src_ver},$maints->{$bvm->{maint}});
 686                 my $b_id = $schema->resultset('BinPkg')->
 687                     get_bin_pkg_id($bvm->{bin});
 688                 my $bv_id = $schema->resultset('BinVer')->
 689                     get_bin_ver_id($b_id,$bvm->{bin_ver},
 690                                    $archs->{$bvm->{arch}},$sv_id);
 691                 $schema->resultset('BinAssociation')->
 692                     insert_suite_bin_ver_association($suite_id,$bv_id);
 693             }
 694         },
 695                         @v
 696                        );
 697         $p->update($p->last_update()+
 698                    scalar @v) if defined $p;
 699     }
 700     if (@bin_to_del) {
 701         $it = natatime 1000, @bin_to_del;
 702         while (my @v = $it->()) {
 703             $schema->
 704                 txn_do(sub {
 705                            $schema->resultset('BinAssociation')->
 706                                search_rs({id => \@v})->
 707                                delete();
 708                        });
 709         }
 710     }
 711     $schema->resultset('BinAssociation')->
 712         search_rs({suite => $suite_id})->
 713         update({modified => 'NOW()'});
 714
 715 }
 716
 717
 718 =back
 719
 720 =cut
 721
 722 =head2 Suites
 723
 724 =over
 725
 726 =item load_suite
 727
 728      load_suite($schema,$codename,$suite,$version,$active);
 729
 730 =cut
 731
 732 sub load_suite {
 733     my ($schema,$codename,$suite,$version,$active) = @_;
 734     if (ref($codename)) {
 735         ($codename,$suite,$version) =
 736             @{$codename}{qw(Codename Suite Version)};
 737         $active = 1;
 738     }
 739     my $s = $schema->resultset('Suite')->find_or_create({codename => $codename});
 740     $s->suite_name($suite);
 741     $s->version($version);
 742     $s->active($active);
 743     $s->update();
 744     return $s;
 745
 746 }
 747
 748 =back
 749
 750 =cut
 751
 752 1;
 753
 754
 755 __END__
 756 # Local Variables:
 757 # indent-tabs-mode: nil
 758 # cperl-indent-level: 4
 759 # End: